P_CL_SalesOriginalJournalEntry

DDL: P_CL_SALESORIGINALJOURNALENTRY Type: view_entity CONSUMPTION Package: GLO_FIN_IS_CL

Original Journal Entry for Chile Sales Ledger

P_CL_SalesOriginalJournalEntry is a Consumption CDS View that provides data about "Original Journal Entry for Chile Sales Ledger" in SAP S/4HANA. It reads from 2 data sources (I_JournalEntry, I_JournalEntryItem) and exposes 13 fields with key fields CompanyCode, FiscalYear, AccountingDocument, FiscalYear, AccountingDocument. Part of development package GLO_FIN_IS_CL.

2 data source(s) 13 fields

Data Sources (2)

SourceAliasJoin Type
I_JournalEntry OriginalJournalEntry inner
I_JournalEntryItem OriginalJrnlEntryItem inner

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
VDM.private true view
VDM.viewType #CONSUMPTION view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode I_JournalEntry CompanyCode
KEY FiscalYear I_JournalEntry FiscalYear
KEY AccountingDocument I_JournalEntry AccountingDocument
ClearingJournalEntry I_JournalEntryItem ClearingJournalEntry
ClearingJournalEntryFiscalYear I_JournalEntryItem ClearingJournalEntryFiscalYear
FinancialAccountType I_JournalEntryItem FinancialAccountType
CompanyCode
KEY FiscalYear I_JournalEntryItem InvoiceReferenceFiscalYear
KEY AccountingDocument I_JournalEntryItem InvoiceReference
ClearingJournalEntry
ClearingJournalEntryFiscalYear
FinancialAccountType I_JournalEntryItem FinancialAccountType
DocumentReferenceID I_JournalEntry DocumentReferenceID 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM: { 
  private: true,
  viewType: #CONSUMPTION
}
define view entity P_CL_SalesOriginalJournalEntry 
  as select distinct from I_JournalEntry     as OriginalJournalEntry
    inner join            I_JournalEntryItem as OriginalJrnlEntryItem on  OriginalJrnlEntryItem.CompanyCode        = OriginalJournalEntry.CompanyCode
                                                                      and OriginalJrnlEntryItem.FiscalYear         = OriginalJournalEntry.FiscalYear
                                                                      and OriginalJrnlEntryItem.AccountingDocument = OriginalJournalEntry.AccountingDocument
{
  key OriginalJournalEntry.CompanyCode,
  key OriginalJournalEntry.FiscalYear,
  key OriginalJournalEntry.AccountingDocument,

      OriginalJrnlEntryItem.ClearingJournalEntry,
      OriginalJrnlEntryItem.ClearingJournalEntryFiscalYear,
      OriginalJrnlEntryItem.FinancialAccountType,
      OriginalJournalEntry.DocumentReferenceID
}
where OriginalJournalEntry.AccountingDocument    <> OriginalJrnlEntryItem.ClearingJournalEntry
  and OriginalJrnlEntryItem.ClearingJournalEntry <> ''

union all select distinct from I_JournalEntryItem as OriginalJrnlEntryItem
  inner join                   I_JournalEntry     as OriginalJournalEntry on  OriginalJrnlEntryItem.CompanyCode                = OriginalJournalEntry.CompanyCode
                                                                          and OriginalJrnlEntryItem.InvoiceReferenceFiscalYear = OriginalJournalEntry.FiscalYear
                                                                          and OriginalJrnlEntryItem.InvoiceReference           = OriginalJournalEntry.AccountingDocument
{
  key OriginalJrnlEntryItem.CompanyCode,
  key OriginalJrnlEntryItem.InvoiceReferenceFiscalYear as FiscalYear,
  key OriginalJrnlEntryItem.InvoiceReference           as AccountingDocument,

      cast ( '' as fis_augbl )                         as ClearingJournalEntry,
      cast ( '0000' as fis_auggj_no_conv )             as ClearingJournalEntryFiscalYear,
      OriginalJrnlEntryItem.FinancialAccountType,
      OriginalJournalEntry.DocumentReferenceID
}
where OriginalJrnlEntryItem.InvoiceReference <> ''

Learn More