P_CADocumentSumClearedItem

DDL: P_CADOCUMENTSUMCLEAREDITEM Type: view_entity COMPOSITE Package: ODATA_O2C_FICA_DOCUMENT_MANAGE

Summarized Cleared Items

P_CADocumentSumClearedItem is a Composite CDS View that provides data about "Summarized Cleared Items" in SAP S/4HANA. It reads from 1 data source (I_CADocumentBPItem) and exposes 20 fields with key fields CAClearingDocumentNumber, CompanyCode, BusinessArea, Division, BusinessPartner. Part of development package ODATA_O2C_FICA_DOCUMENT_MANAGE.

1 data source(s) 20 fields

Data Sources (1)

SourceAliasJoin Type
I_CADocumentBPItem I_CADocumentBPItem from

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Summarized Cleared Items view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #COMPOSITE view
VDM.private true view

Fields (20)

KeyFieldSource TableSource FieldDescription
KEY CAClearingDocumentNumber CAClearingDocumentNumber
KEY CompanyCode CompanyCode
KEY BusinessArea BusinessArea
KEY Division Division
KEY BusinessPartner BusinessPartner
KEY ContractAccount ContractAccount
KEY TransactionCurrency TransactionCurrency
CAAmountInTransactionCurrency
NumberOfCADocumentItems Number
CADocumentNumber
CABPItemNumber
CASubItemNumber
CARepetitionItemNumber
_BusinessArea _BusinessArea
_BusinessPartner _BusinessPartner
_CAClearingDocument _CAClearingDocument
_CompanyCode _CompanyCode
_ContractAccountPartner _ContractAccountPartner
_Division _Division
_TransactionCurrency _TransactionCurrency 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Summarized Cleared Items'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}


@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_CADocumentSumClearedItem
  as select from I_CADocumentBPItem
{
      @ObjectModel.foreignKey.association: '_CAClearingDocument'
  key CAClearingDocumentNumber,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
  key BusinessArea,
      @ObjectModel.foreignKey.association: '_Division'
  key Division,
  key BusinessPartner,
      @ObjectModel.foreignKey.association: '_ContractAccountPartner'
  key ContractAccount,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
  key TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(sum(CAAmountInTransactionCurrency) as betrw_kk) as CAAmountInTransactionCurrency,

      @EndUserText.label: 'Number'
      count(*)                                             as NumberOfCADocumentItems,
      
      cast(max(CADocumentNumber) as opbel_kk) as CADocumentNumber,
      cast(max(CABPItemNumber) as opupk_kk ) as CABPItemNumber,
      cast(max(CASubItemNumber) as opupz_kk ) as CASubItemNumber,
      cast(max(CARepetitionItemNumber) as opupw_kk ) as CARepetitionItemNumber,

      //Associations

      _BusinessArea,
      _BusinessPartner,
      _CAClearingDocument,
      _CompanyCode,
      _ContractAccountPartner,
      _Division,
      _TransactionCurrency
}
where
  CAClearingDocumentNumber <> ''
group by
  CAClearingDocumentNumber,
  CompanyCode,
  BusinessArea,
  Division,
  BusinessPartner,
  ContractAccount,
  TransactionCurrency

Learn More