P_CADocumentSumBPItem

DDL: P_CADOCUMENTSUMBPITEM Type: view_entity COMPOSITE Package: ODATA_O2C_FICA_DOCUMENT_MANAGE

Summarized Business Partner Items

P_CADocumentSumBPItem is a Composite CDS View that provides data about "Summarized Business Partner Items" in SAP S/4HANA. It reads from 1 data source (I_CADocumentBPItem) and exposes 24 fields with key fields CADocumentNumber, BusinessPartner, ContractAccount, CompanyCode, CAApplicationArea. It has 1 association to related views. Part of development package ODATA_O2C_FICA_DOCUMENT_MANAGE.

1 data source(s) 24 fields

Data Sources (1)

SourceAliasJoin Type
I_CADocumentBPItem I_CADocumentBPItem from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_CAClearingReason _CAClearingReason $projection.CAClearingReason = _CAClearingReason.CAClearingReason

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Summarized Business Partner Items view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #P view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #COMPOSITE view
VDM.private true view

Fields (24)

KeyFieldSource TableSource FieldDescription
KEY CADocumentNumber CADocumentNumber
KEY BusinessPartner BusinessPartner
KEY ContractAccount ContractAccount
KEY CompanyCode CompanyCode
KEY CAApplicationArea CAApplicationArea
KEY CAMainTransaction CAMainTransaction
KEY CASubTransaction CASubTransaction
KEY TransactionCurrency TransactionCurrency
CAClearingReason
CAAmountInTransactionCurrency
NumberOfCADocumentBPItems Number
CANetDueDate
CACashDiscountDueDate
CABPItemNumber
CASubItemNumber
CARepetitionItemNumber
_BusinessPartner _BusinessPartner
_CAClearingReason _CAClearingReason
_CADocument _CADocument
_CAMainTransaction _CAMainTransaction
_CASubTransaction _CASubTransaction
_CompanyCode _CompanyCode
_ContractAccountPartner _ContractAccountPartner
_TransactionCurrency _TransactionCurrency 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Summarized Business Partner Items'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #P,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL
}


@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_CADocumentSumBPItem
  as select from I_CADocumentBPItem


  association [0..1] to I_CAClearingReason as _CAClearingReason on $projection.CAClearingReason = _CAClearingReason.CAClearingReason

{
      @ObjectModel.foreignKey.association: '_CADocument'
  key CADocumentNumber,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
  key BusinessPartner,
      @ObjectModel.foreignKey.association: '_ContractAccountPartner'
  key ContractAccount,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
  key CAApplicationArea,
      @ObjectModel.foreignKey.association: '_CAMainTransaction'
  key CAMainTransaction,
      @ObjectModel.foreignKey.association: '_CASubTransaction'
  key CASubTransaction,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
  key TransactionCurrency,

      @ObjectModel.foreignKey.association: '_CAClearingReason'
      cast(max(CAClearingReason) as augrd_kk )             as CAClearingReason,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(sum(CAAmountInTransactionCurrency) as betrw_kk) as CAAmountInTransactionCurrency,

      @EndUserText.label: 'Number'
      count(*)                                             as NumberOfCADocumentBPItems,


      cast(max(CANetDueDate) as faedn_kk)                  as CANetDueDate,

      cast(max(CACashDiscountDueDate) as faeds_kk )        as CACashDiscountDueDate,
      
      cast(max(CABPItemNumber) as opupk_kk ) as CABPItemNumber,
      cast(max(CASubItemNumber) as opupz_kk ) as CASubItemNumber,
      cast(max(CARepetitionItemNumber) as opupw_kk ) as CARepetitionItemNumber,


      //Associations

      _BusinessPartner,
      _CAClearingReason,
      _CADocument,
      _CAMainTransaction,
      _CASubTransaction,
      _CompanyCode,
      _ContractAccountPartner,
      _TransactionCurrency

}
group by
  CADocumentNumber,
  BusinessPartner,
  ContractAccount,
  CompanyCode,
  CAApplicationArea,
  CAMainTransaction,
  CASubTransaction,
  TransactionCurrency

Learn More