P_CADocumentLineItems

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Line Items'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #X,
    sizeCategory: #S,
    dataClass: #MIXED
}
@VDM.private:true
@VDM.viewType: #COMPOSITE
define view entity P_CADocumentLineItems
with parameters           
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate                 : vdm_v_key_date
as select from P_CADocumentLineItem_Split ( P_KeyDate: $parameters.P_KeyDate ) as DOC
inner join I_FiscalCalYearPeriodForCoCode as PER 
  on PER.CompanyCode = DOC.CompanyCode and PER.FiscalPeriodStartDate <= $parameters.P_KeyDate and PER.FiscalPeriodEndDate >= $parameters.P_KeyDate
{
    key DOC.CADocumentNumber,
    key DOC.CARepetitionItemNumber,
    key DOC.CABPItemNumber,
    key DOC.CASubItemNumber,
        DOC.BusinessPartner,
        DOC.ContractAccount,
        DOC.CompanyCode,
        @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
        DOC.CAAmountInLocalCurrency,
        @Semantics.amount.currencyCode: 'TransactionCurrency'
        DOC.CAAmountInTransactionCurrency,                
        DOC.TransactionCurrency,        
        DOC.CompanyCodeCurrency,
        DOC.CAReconciliationAccount,
        DOC.CAPostingDate,
        DOC.CAClearingDate,
        DOC.CAStatisticalItemCode,
        DOC.CAReferenceDocument,
        DOC.DocumentDate,
        DOC.CADocumentType,        
        @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
        DOC.Credit,
        @Semantics.amount.currencyCode: 'CompanyCodeCurrency'  
        DOC.Debit,
        @Semantics.amount.currencyCode: 'TransactionCurrency'
        DOC.CreditTr,
        @Semantics.amount.currencyCode: 'TransactionCurrency'  
        DOC.DebitTr,  
        DOC.CreatedByUser,
        DOC.CASubApplication,
        DOC.CAContract,
        DOC.CADocumentOriginCode,
        DOC.BusinessArea,
        DOC.Segment,        
        DOC._BusinessPartner,        
        DOC._ContractAccountPartner,
        DOC._CAProviderContract                       
}
where DOC.CAPostingDate >= PER.FiscalPeriodStartDate and DOC.CAPostingDate <= PER.FiscalPeriodEndDate and DOC.CAStatisticalItemCode is initial