P_CADocumentIssue1

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'CA Document Issue'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}

@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_CADocumentIssue1
  as select from I_CADunningItem
{
  key cast('01' as docissuetype_kk)                          as CADocumentIssueType,
  key cast('' as lotyp_kk)                                   as CABusinessLockObjectCategory,
  key cast('' as proid_kk)                                   as CABusinessProcess,
  key cast('' as lockr_kk)                                   as CABusinessLockReason,
  key cast('' as fdate_kk)                                   as CABusinessLockValidFrom,
  key cast('' as tdate_kk)                                   as CABusinessLockValidTo,
  key BusinessPartner,
  key ContractAccount,
  key cast('' as vtref_kk)                                   as CAContract,
  key cast('00000000000000000000000000000000' as vtpid_c_kk) as CAProviderContractItemCharUUID,
  key CADocumentNumber,
  key CARepetitionItemNumber,
  key CABPItemNumber,
  key CASubItemNumber,
  key CAMassRunDate,
  key CAMassRunID,
  key CADunningCounter,
  key cast('' as scmg_ext_key)                               as CaseID,
      cast('' as sysuuid_c)                                  as CaseUniqueID,
      cast('' as scmg_case_title)                            as CaseTitle,
      cast('' as proid_kk)                                   as CAAlternativeBusinessProcess,
      cast('' as xfeld)                                      as CABusinessLockIsActive,
      cast('' as xfeld)                                      as CABusinessLockIsRlvtForBPItem,
      CAIssueDate
}

union all

select from P_CADocumentBPItemBusLockEnhcd
{
  key cast('02' as docissuetype_kk) as CADocumentIssueType,
  key CABusinessLockObjectCategory,
  key CABusinessProcess,
  key CABusinessLockReason,
  key CABusinessLockValidFrom,
  key CABusinessLockValidTo,
  key BusinessPartner,
  key ContractAccount,
  key CAContract,
  key CAProviderContractItemCharUUID,
  key CADocumentNumber,
  key CARepetitionItemNumber,
  key CABPItemNumber,
  key CASubItemNumber,
  key cast('' as laufd_kk)          as CAMassRunDate,
  key cast('' as laufi_kk)          as CAMassRunID,
  key cast('' as mazae_kk)          as CADunningCounter,
  key cast('' as scmg_ext_key)      as CaseID,
      cast('' as sysuuid_c)         as CaseUniqueID,
      cast('' as scmg_case_title)   as CaseTitle,
      _LockUI.CAAlternativeBusinessProcess,
      _LockUI.CABusinessLockIsActive,
      _LockUI.CABusinessLockIsRlvtForBPItem,
      cast('' as ausdt_kk) as CAIssueDate
      /* Associations */

}
where
      _LockUI.CABusinessLockIsRlvtForBPItem = 'X'
  and _LockUI.CABusinessLockIsActive         = 'X'

union all

select from P_CADisputeCase
{
  key cast('03' as docissuetype_kk)                          as CADocumentIssueType,
  key cast('' as lotyp_kk)                                   as CABusinessLockObjectCategory,
  key cast('' as proid_kk)                                   as CABusinessProcess,
  key cast('' as lockr_kk)                                   as CABusinessLockReason,
  key cast('' as fdate_kk)                                   as CABusinessLockValidFrom,
  key cast('' as tdate_kk)                                   as CABusinessLockValidTo,
  key BusinessPartner,
  key ContractAccount,
  key cast('' as vtref_kk)                                   as CAContract,
  key cast('00000000000000000000000000000000' as vtpid_c_kk) as CAProviderContractItemCharUUID,
  key CADocumentNumber,
  key cast('' as opupw_kk)                                   as CARepetitionItemNumber,
  key cast('' as opupk_kk)                                   as CABPItemNumber,
  key cast('' as opupz_kk)                                   as CASubItemNumber,
  key cast('' as laufd_kk)                                   as CAMassRunDate,
  key cast('' as laufi_kk)                                   as CAMassRunID,
  key cast('' as mazae_kk)                                   as CADunningCounter,
  key CaseID,
      CaseUniqueID,
      CaseTitle,
      cast('' as proid_kk)                                   as CAAlternativeBusinessProcess,
      cast('' as xfeld)                                      as CABusinessLockIsActive,
      cast('' as xfeld)                                      as CABusinessLockIsRlvtForBPItem,
      cast('' as ausdt_kk) as CAIssueDate
}
where
  ObjectType = 'CA_DOC'