P_BusSolnOrdSrvcOrdFlwLvl2

DDL: P_BUSSOLNORDSRVCORDFLWLVL2 Type: view CONSUMPTION Package: CRMS4_SOLUTION_ORDER_PROGRESS

Solution Order Service Order Flow: Level 2

P_BusSolnOrdSrvcOrdFlwLvl2 is a Consumption CDS View that provides data about "Solution Order Service Order Flow: Level 2" in SAP S/4HANA. It reads from 4 data sources (I_ServiceDocumentItemEnhcd, I_ServiceDocumentItemEnhcd, I_ServiceDocumentItemSuccssr_2, P_BusSolnOrdSrvcOrdFlwLvl1) and exposes 10 fields with key fields PrecedingDocument, PrecedingDocumentItem, PrecedingDocumentCategory, SubsequentDocument, SubsequentDocumentItem. Part of development package CRMS4_SOLUTION_ORDER_PROGRESS.

4 data source(s) 10 fields

Data Sources (4)

SourceAliasJoin Type
I_ServiceDocumentItemEnhcd _ServiceConfirmation inner
I_ServiceDocumentItemEnhcd _ServiceOrder inner
I_ServiceDocumentItemSuccssr_2 _SrvcOrdItmToSrvcConfItm inner
P_BusSolnOrdSrvcOrdFlwLvl1 Level1 from

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName PBSOSOFLWLVL2 view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
VDM.viewType #CONSUMPTION view
VDM.private true view
EndUserText.label Solution Order Service Order Flow: Level 2 view

Fields (10)

KeyFieldSource TableSource FieldDescription
KEY PrecedingDocument P_BusSolnOrdSrvcOrdFlwLvl1 SubsequentDocument
KEY PrecedingDocumentItem P_BusSolnOrdSrvcOrdFlwLvl1 SubsequentDocumentItem
KEY PrecedingDocumentCategory P_BusSolnOrdSrvcOrdFlwLvl1 SubsequentDocumentCategory
KEY SubsequentDocument I_ServiceDocumentItemEnhcd ServiceDocument
KEY SubsequentDocumentItem I_ServiceDocumentItemEnhcd ServiceDocumentItem
KEY SubsequentDocumentCategory
ServiceObjectType P_BusSolnOrdSrvcOrdFlwLvl1 ServiceObjectType
BusinessSolutionOrder BusinessSolutionOrder
ServiceOrder ServiceOrder
ServiceOrderItem ServiceOrderItem 
@AbapCatalog: {
    sqlViewName:            'PBSOSOFLWLVL2',
    compiler.compareFilter: true,
    preserveKey:            true
}

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: {
    dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #XL
}

@VDM: {
    viewType: #CONSUMPTION,
    private:  true
}

@EndUserText.label: 'Solution Order Service Order Flow: Level 2'

// Service Order -> Service Confirmation

define view P_BusSolnOrdSrvcOrdFlwLvl2
  as select from P_BusSolnOrdSrvcOrdFlwLvl1     as Level1

    inner join   I_ServiceDocumentItemEnhcd     as _ServiceOrder            on  _ServiceOrder.ServiceDocument     = Level1.SubsequentDocument
                                                                            and _ServiceOrder.ServiceDocumentItem = Level1.SubsequentDocumentItem

    inner join   I_ServiceDocumentItemSuccssr_2 as _SrvcOrdItmToSrvcConfItm on _SrvcOrdItmToSrvcConfItm.ServiceDocumentItemCharUUID = _ServiceOrder.ServiceDocumentItemCharUUID

    inner join   I_ServiceDocumentItemEnhcd     as _ServiceConfirmation     on _ServiceConfirmation.ServiceDocumentItemCharUUID          = _SrvcOrdItmToSrvcConfItm.ServiceDocItmSuccssrCharUUID
                                                                            and( _SrvcOrdItmToSrvcConfItm.ServiceDocItmSuccssrBusObjType = 'BUS2000142' --> Service Material Confirmation Item
                                                                              or _SrvcOrdItmToSrvcConfItm.ServiceDocItmSuccssrBusObjType = 'BUS2000143' --> Service Product Confirmation Item
                                                                              or _SrvcOrdItmToSrvcConfItm.ServiceDocItmSuccssrBusObjType = 'BUS2000158' --> Service Expense Confirmation Item
                                                                            )
{
  key Level1.SubsequentDocument                as PrecedingDocument,
  key Level1.SubsequentDocumentItem            as PrecedingDocumentItem,
  key Level1.SubsequentDocumentCategory        as PrecedingDocumentCategory,
  key _ServiceConfirmation.ServiceDocument     as SubsequentDocument,
  key _ServiceConfirmation.ServiceDocumentItem as SubsequentDocumentItem,
  key 'CSCO'                                   as SubsequentDocumentCategory,

      // For filtering

      Level1.ServiceObjectType,
      BusinessSolutionOrder,
      ServiceOrder,
      ServiceOrderItem
}

Learn More