P_BusSolnOrdEntProjectFlwLvl2

DDL: P_BUSSOLNORDENTPROJECTFLWLVL2 Type: view CONSUMPTION Package: CRMS4_SOLUTION_ORDER_PROGRESS

Solution Order Enterprise Project Flow: Level 2

P_BusSolnOrdEntProjectFlwLvl2 is a Consumption CDS View that provides data about "Solution Order Enterprise Project Flow: Level 2" in SAP S/4HANA. It reads from 4 data sources (I_EnterpriseProject, I_EnterpriseProjectElement, I_CustProjSlsOrdItem, P_BusSolnOrdEntProjectFlwLvl1) and exposes 12 fields with key fields PrecedingDocument, PrecedingDocumentItem, PrecedingDocumentCategory, SubsequentDocument, SubsequentDocumentItem. Part of development package CRMS4_SOLUTION_ORDER_PROGRESS.

4 data source(s) 12 fields

Data Sources (4)

SourceAliasJoin Type
I_EnterpriseProject _EnterpriseProject inner
I_EnterpriseProjectElement _EnterpriseProjectElement inner
I_CustProjSlsOrdItem _SalesDocumentItem inner
P_BusSolnOrdEntProjectFlwLvl1 Level1 from

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName PBSOEPFLWLVL2 view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
VDM.viewType #CONSUMPTION view
VDM.private true view
EndUserText.label Solution Order Enterprise Project Flow: Level 2 view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY PrecedingDocument P_BusSolnOrdEntProjectFlwLvl1 SubsequentDocument
KEY PrecedingDocumentItem P_BusSolnOrdEntProjectFlwLvl1 SubsequentDocumentItem
KEY PrecedingDocumentCategory P_BusSolnOrdEntProjectFlwLvl1 SubsequentDocumentCategory
KEY SubsequentDocument I_CustProjSlsOrdItem SalesOrder
KEY SubsequentDocumentItem I_CustProjSlsOrdItem SalesOrderItem
KEY SubsequentDocumentCategory
TotalNetAmount
TransactionCurrency
BusinessSolutionOrder P_BusSolnOrdEntProjectFlwLvl1 BusinessSolutionOrder
ServiceObjectType ServiceObjectType
CustomerProject P_BusSolnOrdEntProjectFlwLvl1 CustomerProject
CustomerProjectItem CustomerProjectItem 
@AbapCatalog: {
    sqlViewName:            'PBSOEPFLWLVL2',
    compiler.compareFilter: true,
    preserveKey:            true
}

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: {
    dataClass:      #MIXED,
    serviceQuality: #C,
    sizeCategory:   #XL
}

@VDM: {
    viewType: #CONSUMPTION,
    private: true
}

@EndUserText.label: 'Solution Order Enterprise Project Flow: Level 2'

// Customer Project -> Sales Order

define view P_BusSolnOrdEntProjectFlwLvl2
  as select from P_BusSolnOrdEntProjectFlwLvl1 as Level1
   inner join   I_EnterpriseProject           as _EnterpriseProject        on  _EnterpriseProject.Project = Level1.SubsequentDocument
   inner join   I_EnterpriseProjectElement    as _EnterpriseProjectElement on _EnterpriseProjectElement.ProjectInternalID = _EnterpriseProject.ProjectInternalID
   inner join   I_CustProjSlsOrdItem           as _SalesDocumentItem        on _SalesDocumentItem.WBSElementInternalID = _EnterpriseProjectElement.WBSElementInternalID

{

  key Level1.SubsequentDocument                                 as PrecedingDocument,
  key Level1.SubsequentDocumentItem                             as PrecedingDocumentItem,
  key Level1.SubsequentDocumentCategory                         as PrecedingDocumentCategory,
  key _SalesDocumentItem.SalesOrder                             as SubsequentDocument,
  key _SalesDocumentItem.SalesOrderItem                         as SubsequentDocumentItem,
  key 'CPSO'                                                    as SubsequentDocumentCategory,
  
  @Semantics.amount.currencyCode: 'TransactionCurrency'
  _SalesDocumentItem._SalesOrder.TotalNetAmount,
  _SalesDocumentItem._SalesOrder.TransactionCurrency,

      // For filtering

      Level1.BusinessSolutionOrder,
      ServiceObjectType,
      Level1.CustomerProject,
      CustomerProjectItem

}
where _EnterpriseProjectElement.WBSElementIsBillingElement = 'X'

Learn More