P_BillingDocumentItemBasic_1

@AccessControl.authorizationCheck: #NOT_REQUIRED

@VDM.private: true
@VDM.viewType: #BASIC

define view entity P_BillingDocumentItemBasic_1
  as select from vbrp

{
      // Key

  key vbrp.vbeln                                                           as BillingDocument,
  key vbrp.posnr                                                           as BillingDocumentItem,

      cast(vbrp.pstyv as sales_doc_item_category preserving type)          as SalesDocumentItemCategory,

      vbrp.posar                                                           as SalesDocumentItemType,
      vbrp.shkzg                                                           as ReturnItemProcessingType,
      // Admin      

      vbrp.ernam                                                           as CreatedByUser,
      vbrp.erdat                                                           as CreationDate,
      vbrp.erzet                                                           as CreationTime,
      vbrp.logsys                                                          as ReferenceLogicalSystem,
      cast(vbrp.spara as sales_order_divison preserving type)              as OrganizationDivision,
      vbrp. spart                                                          as Division,
      vbrp.vkbur                                                           as SalesOffice,
      cast(vbrp.matnr as productnumber preserving type)                    as Product,

      vbrp.matwa                                                           as OriginallyRequestedMaterial,
      vbrp.ean11                                                           as InternationalArticleNumber,

      vbrp.pmatn                                                           as PricingReferenceMaterial,

      vbrp.charg                                                           as Batch,

      vbrp.prodh                                                           as ProductHierarchyNode,

      cast(vbrp.matkl as productgroup preserving type)                     as ProductGroup,

      vbrp.mvgr1                                                           as AdditionalMaterialGroup1,
      vbrp.mvgr2                                                           as AdditionalMaterialGroup2,
      vbrp.mvgr3                                                           as AdditionalMaterialGroup3,
      vbrp.mvgr4                                                           as AdditionalMaterialGroup4,
      vbrp.mvgr5                                                           as AdditionalMaterialGroup5,
      vbrp.cuobj                                                           as ProductConfiguration,
      vbrp.provg                                                           as MaterialCommissionGroup,
      vbrp.werks                                                           as Plant,
      vbrp.lgort                                                           as StorageLocation,
      vbrp.atpkz                                                           as ReplacementPartType,
      vbrp.wgru1                                                           as MaterialGroupHierarchy1,
      vbrp.wgru2                                                           as MaterialGroupHierarchy2,
      vbrp.wkreg                                                           as PlantRegion,
      vbrp.wkcou                                                           as PlantCounty,
      vbrp.wkcty                                                           as PlantCity,
      vbrp.transit_plant                                                   as TransitPlant,
      vbrp.vcm_chain_category                                              as ValueChainCategory,
      vbrp.sernr                                                           as BOMExplosion,
      vbrp.prosa                                                           as MaterialDeterminationType,

      // Billing

      @Semantics.text: true
      vbrp.arktx                                                           as BillingDocumentItemText,

      vbrp.fbuda                                                           as ServicesRenderedDate,

      @Semantics.quantity.unitOfMeasure: 'BillingQuantityUnit'
      vbrp.fkimg                                                           as BillingQuantity,

      vbrp.vrkme                                                           as BillingQuantityUnit,

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      vbrp.fklmg                                                           as BillingQuantityInBaseUnit,

      vbrp.meins                                                           as BaseUnit,

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      vbrp.lmeng                                                           as MRPRequiredQuantityInBaseUnit,

      vbrp.umvkn                                                           as BillingToBaseQuantityDnmntr,
      vbrp.umvkz                                                           as BillingToBaseQuantityNmrtr,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      vbrp.brgew                                                           as ItemGrossWeight,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      vbrp.ntgew                                                           as ItemNetWeight,

      vbrp.gewei                                                           as ItemWeightUnit,

      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      vbrp.volum                                                           as ItemVolume,

      vbrp.voleh                                                           as ItemVolumeUnit,
      vbrp.lland_auft                                                      as BillToPartyCountry,
      vbrp.regio_auft                                                      as BillToPartyRegion,
      vbrp.fareg                                                           as BillingPlanRule,
      vbrp.fplnr                                                           as BillingPlan,
      vbrp.fpltr                                                           as BillingPlanItem,
      vbrp.dwn_payt_procg_var                                              as DownPaymentProcessingVariant,
      vbrp.fksaa                                                           as DocumentBillingStatus,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.netwr                                                           as NetAmount,

      vbrp.waerk                                                           as TransactionCurrency,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.brtwr                                                           as GrossAmount,

      vbrp.prsdt                                                           as PricingDate,
      cast(vbrp.kursk as kursk_not_converted preserving type)              as PriceDetnExchangeRate,

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      vbrp.smeng                                                           as PricingScaleQuantityInBaseUnit,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.mwsbp                                                           as TaxAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.wavwr                                                           as CostAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.kzwi1                                                           as Subtotal1Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.kzwi2                                                           as Subtotal2Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.kzwi3                                                           as Subtotal3Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.kzwi4                                                           as Subtotal4Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.kzwi5                                                           as Subtotal5Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.kzwi6                                                           as Subtotal6Amount,

      vbrp.kowrr                                                           as StatisticalValueControl,
      vbrp.sktof                                                           as CashDiscountIsDeductible,
      vbrp.kdkg1                                                           as CustomerConditionGroup1,
      vbrp.kdkg2                                                           as CustomerConditionGroup2,
      vbrp.kdkg3                                                           as CustomerConditionGroup3,
      vbrp.kdkg4                                                           as CustomerConditionGroup4,
      vbrp.kdkg5                                                           as CustomerConditionGroup5,
      vbrp.mprok                                                           as ManualPriceChangeType,
      vbrp.kondm                                                           as MaterialPricingGroup,
      cast(vbrp.stcur as stcur_ap_not_converted preserving type)           as StatisticsExchangeRate,
      vbrp.upmat                                                           as MainItemPricingRefMaterial,
      vbrp.ukonm                                                           as MainItemMaterialPricingGroup,
      vbrp.cats_overtime_category                                          as TimeSheetOvertimeCategory,
      vbrp.prsfd                                                           as PricingRelevance,
      vbrp.aland                                                           as DepartureCountry,
      vbrp.txjcd                                                           as TaxJurisdiction,
      cast(vbrp.taxm1 as product_tax_classification_1 preserving type)     as ProductTaxClassification1,
      cast(vbrp.taxm2 as product_tax_classification_2 preserving type)     as ProductTaxClassification2,
      cast(vbrp.taxm3 as product_tax_classification_3 preserving type)     as ProductTaxClassification3,
      cast(vbrp.taxm4 as product_tax_classification_4 preserving type)     as ProductTaxClassification4,
      cast(vbrp.taxm5 as product_tax_classification_5 preserving type)     as ProductTaxClassification5,
      cast(vbrp.taxm6 as product_tax_classification_6 preserving type)     as ProductTaxClassification6,
      cast(vbrp.taxm7 as product_tax_classification_7 preserving type)     as ProductTaxClassification7,
      cast(vbrp.taxm8 as product_tax_classification_8 preserving type)     as ProductTaxClassification8,
      cast(vbrp.taxm9 as product_tax_classification_9 preserving type)     as ProductTaxClassification9,
      vbrp.j_1arfz                                                         as ZeroVATRsn,
      vbrp.mwsk1                                                           as TaxCode,
      vbrp.txdat_from                                                      as TaxRateValidityStartDate,
      vbrp.spe_herkl                                                       as CountryOfOrigin,
      vbrp.spe_herkr                                                       as RegionOfOrigin,
      vbrp.itm_comco                                                       as CommodityCode,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.skfbp                                                           as EligibleAmountForCashDiscount,

      vbrp.gsber                                                           as BusinessArea,
      vbrp.prctr                                                           as ProfitCenter,
      cast(vbrp.ps_psp_pnr as ps_s4_pspnr preserving type)                 as WBSElementInternalID,
      vbrp.vtkey                                                           as ProviderContract,
      cast(vbrp.vtpos as provider_contract_item preserving type)           as ProviderContractItem,
      vbrp.perop_beg                                                       as BillingPerformancePeriodStrDte,
      vbrp.perop_end                                                       as BillingPerformancePeriodEndDte,
      vbrp.kokrs                                                           as ControllingArea,
      cast(vbrp.paobjnr as rkeobjnr_char)                                  as ProfitabilitySegment_2,
      vbrp.aufnr                                                           as OrderID,
      vbrp.kostl                                                           as CostCenter,
      vbrp.vbelv                                                           as OriginSDDocument,
      vbrp.posnv                                                           as OriginSDDocumentItem,
      vbrp.kursk_dat                                                       as PriceDetnExchangeRateDate,
      vbrp.ktgrm                                                           as MatlAccountAssignmentGroup,

      // Reference

      vbrp.vgbel                                                           as ReferenceSDDocument,
      vbrp.vgpos                                                           as ReferenceSDDocumentItem,
      cast(vbrp.vgtyp as reference_doc_category preserving type)           as ReferenceSDDocumentCategory,
      vbrp.aubel                                                           as SalesDocument,
      vbrp.aupos                                                           as SalesDocumentItem,
      cast(vbrp.autyp as sales_document_category preserving type)          as SalesSDDocumentCategory,
      vbrp.uepos                                                           as HigherLevelItem,
      vbrp.uecha                                                           as HigherLvlItmOfBatSpltItm,
      vbrp.pospa                                                           as BillingDocumentItemInPartSgmt,
      cast(vbrp.vgbel_ex as ext_reference_document preserving type)        as ExternalReferenceDocument,
      cast(vbrp.vgpos_ex as billingdocextreferencedocitem preserving type) as BillingDocExtReferenceDocItem,
      vbrp.pbd_id                                                          as PrelimBillingDocument,
      vbrp.pbd_item_id                                                     as PrelimBillingDocumentItem,

      // Sales

      vbrp.vkgrp                                                           as SalesGroup,
      vbrp.kvgr1                                                           as AdditionalCustomerGroup1,
      vbrp.kvgr2                                                           as AdditionalCustomerGroup2,
      vbrp.kvgr3                                                           as AdditionalCustomerGroup3,
      vbrp.kvgr4                                                           as AdditionalCustomerGroup4,
      vbrp.kvgr5                                                           as AdditionalCustomerGroup5,
      vbrp.augru_auft                                                      as SDDocumentReason,
      vbrp.aktnr                                                           as RetailPromotion,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.bonba                                                           as RebateBasisAmount,

      vbrp.bonus                                                           as VolumeRebateGroup,
      vbrp.cmpnt                                                           as ItemIsRelevantForCredit,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      vbrp.cmpre                                                           as CreditRelatedPrice,

      vbrp.knuma_ag                                                        as SalesDeal,
      vbrp.knuma_pi                                                        as SalesPromotion,
      vbrp.bzirk_auft                                                      as SalesOrderSalesDistrict,
      vbrp.kdgrp_auft                                                      as SalesOrderCustomerGroup,
      vbrp.konda_auft                                                      as SalesOrderCustomerPriceGroup,
      vbrp.pltyp_auft                                                      as SalesOrderPriceListType,
      vbrp.vkorg_auft                                                      as SalesOrderSalesOrganization,
      vbrp.vtweg_auft                                                      as SalesOrderDistributionChannel,
      vbrp.auref                                                           as SalesDocIsCreatedFromReference,
      vbrp.vstel                                                           as ShippingPoint,
      vbrp.service_doc_type                                                as ServiceDocumentType,
      vbrp.service_doc_id                                                  as ServiceDocument,
      vbrp.service_doc_item_id                                             as ServiceDocumentItem,

      vbrp.solution_order_id                                               as BusinessSolutionOrder,
      vbrp.solution_order_item_id                                          as BusinessSolutionOrderItem,

      // Other fields

      vbrp.uepvw                                                           as HigherLevelItemUsage,
      cast(vbrp.draft as vf_draft_indicator preserving type)               as BillingDocumentIsTemporary,

      // Added Analytics fields

      vbrp.vbtyp_ana                                                       as SDDocumentCategory,
      vbrp.fkart_ana                                                       as BillingDocumentType,
      vbrp.vkorg_ana                                                       as SalesOrganization,
      vbrp.vtweg_ana                                                       as DistributionChannel,
      vbrp.konda_ana                                                       as CustomerPriceGroup,
      vbrp.kdgrp_ana                                                       as CustomerGroup,
      vbrp.land1_ana                                                       as Country,
      vbrp.regio_ana                                                       as Region,
      vbrp.cityc_ana                                                       as CityCode,
      vbrp.bzirk_ana                                                       as SalesDistrict,
      vbrp.gbstk_ana                                                       as OverallSDProcessStatus,
      vbrp.vf_status_ana                                                   as OverallBillingStatus,
      vbrp.kunag_ana                                                       as SoldToParty,
      vbrp.kunrg_ana                                                       as PayerParty,
      vbrp.fkdat_ana                                                       as BillingDocumentDate,
      vbrp.bukrs_ana                                                       as CompanyCode,
      vbrp.counc_ana                                                       as County,
      vbrp.knuma_ana                                                       as CustomerRebateAgreement,
      vbrp.fktyp_ana                                                       as BillingDocumentCategory,
      vbrp.kunwe_ana                                                       as ShipToParty,
      vbrp.kunre_ana                                                       as BillToParty,
      vbrp.perve_ana                                                       as SalesEmployee,
      vbrp.perzm_ana                                                       as ResponsibleEmployee,
      vbrp.knumv_ana                                                       as PricingDocument,
      vbrp.sfakn_ana                                                       as CancelledBillingDocument,
      vbrp.sold_product                                                    as SoldProduct,
      vbrp.prefe                                                           as CustomsPreference,
      vbrp.pref_stmnt                                                      as TrdPrefStmntExternalOriginCode,
      vbrp.pref_stmnt_code                                                 as TrdPrefStmntInternalOriginCode
}