P_BillOfMaterialHeaderDEX

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Data extraction Header'
@Metadata.ignorePropagatedAnnotations: true
@VDM.private: true
@VDM.viewType: #BASIC
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}

define view entity P_BillOfMaterialHeaderDEX
  as select from stko
    inner join   stzu as stzu on  stko.stlty = stzu.stlty
                              and stko.stlnr = stzu.stlnr
{
  key stko.stlty                                 as BillOfMaterialCategory,
  key cast(stko.stlnr as char8 preserving type ) as BillOfMaterial,
  key stko.stlal                                 as BillOfMaterialVariant,
  key stko.stkoz                                 as BOMHeaderInternalChangeCount,
      stzu.stlan                                 as BillOfMaterialVariantUsage,
      stko.bom_versn                             as BillOfMaterialVersion,
      stzu.stlbe                                 as BillOfMaterialAuthsnGrp,
      stzu.kbaus                                 as BOMIsConfigurable,
      stzu.kbaus                                 as IsConfiguredMaterial,
      stzu.versnind                              as IsVersionBillOfMaterial,
      cast( case
        when stzu.altst = 'X' then 'M'
        when stzu.varst = 'X' then 'V'
        else ' '
        end   as tetyp_d preserving type )       as BOMTechnicalType,
      stzu.ztext                                 as BOMHeaderText,
      stzu.exstl                                 as BOMGroup,
      stzu.hisdt                                 as IndicatorIsBOMWithDateHistory,
      stzu.histk                                 as IndicatorIsBOMChangedWithHist,
      stko.datuv                                 as HeaderValidityStartDate,
      stko.aennr                                 as HeaderEngineeringChgNmbrDoc,
      stko.lkenz                                 as DeletionIndicator,
      stko.loekz                                 as BOMIsArchivedForDeletion,
      stko.andat                                 as RecordCreationDate,
      stko.annam                                 as CreatedByUser,
      stko.aedat                                 as LastChangeDate,
      stko.aenam                                 as LastChangedByUser,
      stko.bmein                                 as BOMHeaderBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BOMHeaderBaseUnit'
      stko.bmeng                                 as BOMHeaderQuantityInBaseUnit,
      stko.cadkz                                 as DocumentIsCreatedByCAD,
      stko.labor                                 as LaboratoryOrDesignOffice,
      stko.ltxsp                                 as LongTextLanguage,
      stko.stktx                                 as BOMAlternativeText,
      stko.stlst                                 as BillOfMaterialStatus,
      stko.wrkan                                 as BOMOrBOMAltvCrtedInPlnt,
      stko.alekz                                 as IsALE,
      stko.guidx                                 as BillOfMaterialHeaderUUID,
      stko.valid_to                              as HeaderValidityEndDate,
      stko.ecn_to                                as ChgToEngineeringChgDocument,
      stko.versnst                               as BOMVersionStatus,
      stko.versnlastind                          as IsLatestBOMVersion,
      stko.lastchangedatetime                    as LastChangeDateTime,
      stko.bom_ain_ind                           as BOMAssetNtwkHndovrIsRelevant,
      stko.bom_prev_versn                        as BOMPredecessorVersion

}