P_BG_SAFTPURINVOICEHEADER

@AbapCatalog.viewEnhancementCategory: [#NONE]
@VDM.viewType: #CONSUMPTION
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity P_BG_SAFTPURINVOICEHEADER
  with parameters

    P_AlternativeGLAccountIsUsed : saft_bg_alt_gl_account_flag,
    P_UserSystemIdentifier       : sysid,
    P_VATRegistration            : stceg

  as select from           P_BG_SAFTPURINVHDR        as Header

    inner join             I_JournalEntry            as Bkpf             on  Bkpf.AccountingDocument     = Header.AccountingDocument
                                                                         and Bkpf.CompanyCode            = Header.CompanyCode
                                                                         and Bkpf.FiscalYear             = Header.FiscalYear
                                                                         and Bkpf.AccountingDocumentType = Header.AccountingDocumentType
                                                                         and Bkpf.PostingDate            = Header.PostingDate

    inner join             I_OperationalAcctgDocItem as Bseg             on  Bseg.AccountingDocument     = Header.AccountingDocument
                                                                         and Bseg.CompanyCode            = Header.CompanyCode
                                                                         and Bseg.FiscalYear             = Header.FiscalYear
                                                                         and Bseg.AccountingDocumentItem = Header.AccountingDocumentItem
                                                                         and Bseg.AccountingDocumentType = Header.AccountingDocumentType
                                                                         and Bseg.PostingDate            = Header.PostingDate

    inner join             P_BG_SAFTINVOICEITEMCOUNT as CountFilter      on  CountFilter.AccountingDocument     = Header.AccountingDocument
                                                                         and CountFilter.FiscalYear             = Header.FiscalYear
                                                                         and CountFilter.CompanyCode            = Header.CompanyCode
                                                                         and CountFilter.PostingDate            = Header.PostingDate
                                                                         and CountFilter.AccountingDocumentType = Header.AccountingDocumentType


    left outer to one join I_Supplier                as Supplier         on Supplier.Supplier = Bseg.Supplier

  // Supplier country

    left outer to one join I_Country                 as BsegStcegCountry on BsegStcegCountry.Country = left(
      Bseg.VATRegistration, 2
    )

  // Supplier specific table with Supplier VAT number information

    left outer to one join P_BG_SAFTSUPPLIERID       as TaxType          on TaxType.Supplier = Bseg.Supplier

    left outer to one join I_PaymentTerms            as PayTerms         on Bseg.PaymentTerms = PayTerms.PaymentTerms

    left outer to one join I_BG_SAFTOneTimeSupplier  as OTC              on  OTC.AccountingDocument     = Bseg.AccountingDocument
                                                                         and OTC.CompanyCode            = Bseg.CompanyCode
                                                                         and OTC.FiscalYear             = Bseg.FiscalYear
                                                                         and OTC.AccountingDocumentItem = Bseg.AccountingDocumentItem

{
  key Header.SourceLedger,
  key Header.CompanyCode,
  key Header.FiscalYear,
  key Header.AccountingDocument,
  key Header.Ledger,
      Header.AccountingDocumentItem,
      Bkpf.FiscalPeriod,
      Bkpf.PostingDate,
      Bkpf.DocumentDate                                                                                                                                                 as InvoiceDate,
      Bkpf.TaxReportingDate,
      Bkpf.AccountingDocumentType,
      Bkpf.AccountingDocCreatedByUser,
      Supplier.Supplier,
      case when TaxType.BPTaxLongNumber <> '0' then concat_with_space( Supplier.BPAddrStreetName, Supplier._AddressDefaultRepresentation.HouseNumber, 1 )
        else coalesce(OTC.StreetName, concat_with_space( Supplier.BPAddrStreetName, Supplier._AddressDefaultRepresentation.HouseNumber, 1 ))
      end                                                                                                                                                               as StreetName,
      case when TaxType.BPTaxLongNumber <> '0' then Supplier.BPAddrCityName
        else coalesce(OTC.CityName, Supplier.BPAddrCityName)
      end                                                                                                                                                               as CityName,
      case when TaxType.BPTaxLongNumber <> '0' then Supplier.PostalCode
        else coalesce(OTC.PostalCode, Supplier.PostalCode)
      end                                                                                                                                                               as PostalCode,
      case when TaxType.BPTaxLongNumber <> '0' then Supplier.Country
        else coalesce(OTC.Country, Supplier.Country)
      end                                                                                                                                                               as Country,

      Header.BG_SAFTSourceDocumentType                                                                                                                                  as BG_SAFTInvoiceType,

      case
        when Bseg.VATRegistration <> '' and BsegStcegCountry.IsEuropeanUnionMember = 'X' then
          case
            when BsegStcegCountry.Country = 'BG' then replace(Bseg.VATRegistration, 'BG', '10')
            else cast(concat('11', Bseg.VATRegistration) as bptaxnumxl)
          end
        when TaxType.BPTaxLongNumber = 'EXCLUDE' then cast($parameters.P_VATRegistration as bptaxnumxl)
        when TaxType.BPTaxLongNumber <> '0' then TaxType.BPTaxLongNumber
        else OTC.VATRegistration
      end                                                                                                                                                               as SupplierTaxID5,

      case $parameters.P_AlternativeGLAccountIsUsed
      when 'X' then Bseg._CompanyCode.CountryChartOfAccounts
      else Bseg.ChartOfAccounts
      end                                                                                                                                                               as ActiveChartOfAccounts,
      case $parameters.P_AlternativeGLAccountIsUsed
        when 'X' then Bseg._GLAccountInCompanyCode.AlternativeGLAccount
        else Bseg.GLAccount
      end                                                                                                                                                               as ActiveGLAccount,

      cast(concat( $parameters.P_UserSystemIdentifier, concat( concat( concat( '/', cast( $session.client as char3 )), '/' ) , Header.AccountingDocument ) ) as text18) as BG_SAFTSystemID,

      coalesce(PayTerms._Text[1: Language='W'].PaymentTermsName, PayTerms._Text[1: Language='E'].PaymentTermsName)                                                      as PaymentTermsName,

      'N'                                                                                                                                                               as SelfBillingValueItemDesc,

      concat(
        concat( Header.CompanyCode, Header.FiscalYear ),
        concat( Header.AccountingDocumentType, Header.AccountingDocument )
      )                                                                                                                                                                 as BusinessTransactionTypeName,

      cast(
        case
          when Bkpf.AlternativeReferenceDocument <> '' then Bkpf.AlternativeReferenceDocument
          when Bkpf.DocumentReferenceID <> '' then Bkpf.DocumentReferenceID
          else Bkpf.AccountingDocument
        end
      as fis_xblnr_alt_alpha)                                                                                                                                           as AlternativeReferenceDocument
}