P_AssetClassByCompanyCode

@AbapCatalog: { sqlViewName: 'PCOMPCODEASSETCL', preserveKey: true, compiler.compareFilter: true }
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view P_AssetClassByCompanyCode
  as select distinct from   I_CompanyCodeAsset
    left outer to many join I_AssetClassDepreciationArea on I_CompanyCodeAsset.ChartOfDepreciation = I_AssetClassDepreciationArea.ChartOfDepreciation
    inner join              I_AssetRedesignSwitchStatus  on I_AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = ''
{
  key I_CompanyCodeAsset.CompanyCode,
  key I_AssetClassDepreciationArea.AssetClass,

      cast('' as anlue)                   as FixedAssetGroup,
      cast('' as faa_layout)              as AssetScreenLayout,
      cast('' as faa_downpayment_allowed) as AssetClassDownPaymentIsAllowed,
      cast('' as xspea_anka)              as AssetClassIsBlocked,
      cast('' as  inken)                  as InventoryIsCounted,
      cast('' as eigkz)                   as FixedAssetPropertyType,
      cast('' as vmgli)                   as PropertyClass,
      cast('' as feins)                   as AreaSizeUnit
}
where
  I_AssetClassDepreciationArea.AssetClassIsBlocked <> 'X'

union all select from P_TF_AssetClassByCompanyCode( P_SAPClient: $session.client )
  inner join          I_AssetRedesignSwitchStatus on I_AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = 'X'
{
  key CompanyCode,
  key AssetClass,

      FixedAssetGroup,
      AssetScreenLayout,
      AssetClassDownPaymentIsAllowed,
      AssetClassIsBlocked,
      InventoryIsCounted,
      FixedAssetPropertyType,
      PropertyClass,
      AreaSizeUnit
}