P_AR_SuplrPaymentPartialFull2

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view entity P_AR_SuplrPaymentPartialFull2
  as select from           P_AR_SuplrPaymentPartialFull as PaymentItem

    inner join             I_OperationalAcctgDocItem    as RelatedItem       on  RelatedItem.CompanyCode            = PaymentItem.CompanyCode
                                                                             and RelatedItem.FiscalYear             = PaymentItem.RelatedDocumentFiscalYear
                                                                             and RelatedItem.AccountingDocument     = PaymentItem.ReltdDocAccountingDocument
                                                                             and RelatedItem.AccountingDocumentItem = PaymentItem.RelatedDocumentItemNumber

    left outer to one join I_OperationalAcctgDocItem    as PartiallyPaidItem on  PartiallyPaidItem.CompanyCode          = RelatedItem.CompanyCode
                                                                             and PartiallyPaidItem.FiscalYear           = RelatedItem.InvoiceReferenceFiscalYear
                                                                             and PartiallyPaidItem.AccountingDocument   = RelatedItem.InvoiceReference
                                                                             and PartiallyPaidItem.FinancialAccountType = 'K'
                                                                             and PaymentItem.ReltdSpclGLTransacType     = 'P' // Payment Request


{
  key PaymentItem.StatryRptgEntity,
  key PaymentItem.StatryRptCategory,
  key PaymentItem.StatryRptRunID,
  key PaymentItem.CompanyCode,
  key PaymentItem.FiscalYear,
  key PaymentItem.AccountingDocument,
  key PaymentItem.AccountingDocumentItem,
  key PaymentItem.ClearingInformationIndex,
  key PaymentItem.PaidItemClearingInfoIndex,

  key cast(
        case
          when PartiallyPaidItem.AccountingDocument is not null then PartiallyPaidItem.AccountingDocument
          when PartiallyPaidItem.AccountingDocument is null then RelatedItem.AccountingDocument
        end as fis_belnr_rel_doc preserving type )               as ReltdDocAccountingDocument,

  key cast(
        case
          when PartiallyPaidItem.AccountingDocumentItem is not null then PartiallyPaidItem.AccountingDocumentItem
          when PartiallyPaidItem.AccountingDocumentItem is null then RelatedItem.AccountingDocumentItem
        end as fis_buzei preserving type )                       as RelatedDocumentItemNumber,

      cast(
        case
          when PartiallyPaidItem.FiscalYear is not null then PartiallyPaidItem.FiscalYear
          when PartiallyPaidItem.FiscalYear is null then RelatedItem.FiscalYear
        end as fis_gjahr_rel_doc preserving type )               as RelatedDocumentFiscalYear,

      cast(
        case
          when PartiallyPaidItem.TransactionCurrency is not null then PartiallyPaidItem.TransactionCurrency
          when PartiallyPaidItem.TransactionCurrency is null then RelatedItem.TransactionCurrency
        end as fiar_reltd_document_trans_crcy  preserving type ) as ReltdDocTransactionCurrency,

      @Semantics.amount.currencyCode: 'ReltdDocTransactionCurrency'
      cast(
        case
          when PartiallyPaidItem.AmountInTransactionCurrency is not null then abs(PartiallyPaidItem.AmountInTransactionCurrency)
          when PartiallyPaidItem.AmountInTransactionCurrency is null then abs(RelatedItem.AmountInTransactionCurrency)
        end as fiar_reltd_doc_amnt_trans_crcy  preserving type ) as ReltdDocAmtInTransCurrency,

      cast(
        case
          when PartiallyPaidItem.Supplier is not null then PartiallyPaidItem.Supplier
          when PartiallyPaidItem.Supplier is null then RelatedItem.Supplier
        end as md_supplier preserving type )                     as Supplier,

      cast(
        case
          when PartiallyPaidItem.GLAccount is not null then PartiallyPaidItem.GLAccount
          when PartiallyPaidItem.GLAccount is null then RelatedItem.GLAccount
        end as fis_racct preserving type )                       as GLAccount,

      cast(
        case
          when PaymentItem.PaymentMethod is not null then PaymentItem.PaymentMethod
          when PaymentItem.PaymentMethod is null then RelatedItem.PaymentMethod
        end as farp_schzw_bseg preserving type )                 as PaymentMethod,

      PaymentItem.PaymentDate,
      PaymentItem.CompanyCodeCountry,
      PaymentItem.CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PaymentItem.PaytAmountInCoCodeCurrency,
      PaymentItem.ReltdSpclGLTransacType,
      PaymentItem.HouseBank,
      PaymentItem.PaymentGLAccount,
      PaymentItem._GLAccountInCompanyCode

}