P_ARPCurRole

@AbapCatalog.sqlViewName: 'PARPCURROLE'
@VDM.viewType: #BASIC
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_ARPCurRole
  as select from I_CompanyCode as _CompanyCode

  association [0..1] to t001a       as _CompanyCurrencyControl on $projection.CompanyCode = _CompanyCurrencyControl.bukrs
  association [0..1] to I_SAPClient as _SAPClient              on _CompanyCode.mandt = _SAPClient.sapclient
  association [0..1] to t005        as _Countries              on _CompanyCode.Country = _Countries.land1
  association [0..1] to t880        as _GlobalCompanyData      on _CompanyCode.Company = _GlobalCompanyData.rcomp
{
  key CompanyCode,
      CompanyCodeName,

      cast(
        case _CompanyCurrencyControl.curtp
            when '11' then _CompanyCode.Currency
            when '12' then _CompanyCode.Currency
            when '30' then _SAPClient.GroupCurrency
            when '31' then _SAPClient.GroupCurrency
            when '32' then _SAPClient.GroupCurrency
            when '40' then _Countries.curha
            when '50' then _Countries.curin
            when '60' then _GlobalCompanyData.curr
            else ''
        end as fis_hwae2 )                           as AdditionalCurrency1,

      cast(
        case _CompanyCurrencyControl.curtp2
            when '11' then _CompanyCode.Currency
            when '12' then _CompanyCode.Currency
            when '30' then _SAPClient.GroupCurrency
            when '31' then _SAPClient.GroupCurrency
            when '32' then _SAPClient.GroupCurrency
            when '40' then _Countries.curha
            when '50' then _Countries.curin
            when '60' then _GlobalCompanyData.curr
            else ''
        end as fis_hwae3 )                           as AdditionalCurrency2,
      
      cast( _CompanyCurrencyControl.curtp  as fis_adl1_currole preserving type )  as AdditionalCurrency1Role,
      cast( _CompanyCurrencyControl.curtp2 as fis_adl2_currole preserving type )  as AdditionalCurrency2Role
}