N_PersonWorkAgreement_2

@AbapCatalog.sqlViewName: 'NPERSWKAGRMT2'
@VDM.auxiliaryEntity.for.entity: 'I_PersonWorkAgreement_2'
@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Auxillary View for New Persistency'
define view N_PersonWorkAgreement_2 
as select from P_N_HrPersWrkAgrmt        as HrPersonWorkAgreement
    inner join   P_N_PersWrkAgrmtToPartner as PersonWrkAgrmtToPartner on PersonWrkAgrmtToPartner.PersonWorkAgreement = HrPersonWorkAgreement.PersonWorkAgreement

    inner join   I_BusinessPartner       as BusinessPartner         on  BusinessPartner.BusinessPartner         = PersonWrkAgrmtToPartner.Person
                                                                    and BusinessPartner.BusinessPartnerCategory = '1'

  association [1]    to I_BusinessPartner              as _BusinessPartner              on $projection.Person = _BusinessPartner.BusinessPartner
  association [1]    to I_PersonWorkAgrmtForKeyDate    as _PersonWrkAgrmtForKeyDate     on $projection.PersonWorkAgreement = _PersonWrkAgrmtForKeyDate.PersonWorkAgreement
  association [1]    to I_WorkforcePerson              as _WorkforcePerson              on $projection.Person = _WorkforcePerson.Person
  association [1..*] to I_PersonWorkAgrmtToExternalID  as _PersonWorkAgrmtToExternalID  on $projection.PersonWorkAgreement = _PersonWorkAgrmtToExternalID.PersonWorkAgreement
  association [1..*] to I_PersonWorkAgrmtOrglDetails   as _PersonWorkAgrmtOrglDetails   on _PersonWorkAgrmtOrglDetails.PersonWorkAgreement = $projection.PersonWorkAgreement
  association [1..*] to I_PersonWorkAgrmtStatus        as _PersonWorkAgrmtStatus        on _PersonWorkAgrmtStatus.PersonWorkAgreement = $projection.PersonWorkAgreement
  association [0..*] to I_PersonWorkAgrmtPlndWrkgTime  as _PersonWorkAgrmtPlndWrkgTime  on _PersonWorkAgrmtPlndWrkgTime.PersonWorkAgreement = $projection.PersonWorkAgreement
  association [0..*] to I_PersonWorkAgrmtSrvcCostLevel as _PersonWorkAgrmtSrvcCostLevel on _PersonWorkAgrmtSrvcCostLevel.PersonWorkAgreement = $projection.PersonWorkAgreement
  association [0..*] to I_PersWrkAgrmtManagerForKeyDte as _PersWrkAgrmtManagerForKeyDte on $projection.PersonWorkAgreement = _PersWrkAgrmtManagerForKeyDte.PersonWorkAgreement
  association [1]    to I_PersonWorkAgreementType      as _PersonWorkAgreementType      on $projection.PersonWorkAgreement = _PersonWorkAgreementType.PersonWorkAgreement

{
       @ObjectModel.text.element: 'PersonFullName'
  key  HrPersonWorkAgreement.PersonWorkAgreement                  as  PersonWorkAgreement,
       BusinessPartner.BusinessPartner                            as  Person,
       BusinessPartner.AuthorizationGroup,
       @Semantics.text
       BusinessPartner.PersonFullName,
       _PersonWrkAgrmtForKeyDate,
       _PersonWorkAgrmtToExternalID,
       _BusinessPartner,
       _WorkforcePerson,
       _PersonWorkAgrmtOrglDetails,
       _PersonWorkAgrmtStatus,
       _PersonWorkAgrmtPlndWrkgTime,
       _PersonWorkAgrmtSrvcCostLevel,
       _PersWrkAgrmtManagerForKeyDte,
       _PersonWorkAgreementType
}