N_ChgRecdObjPgMaintTskList

@AbapCatalog.sqlViewName:'NCHGRCDOBJPGMTL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Auxillary view Maint Tsk List'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AbapCatalog.preserveKey:true
@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant']
}

@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass:  #CUSTOMIZING,
                          sizeCategory: #S}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@VDM.auxiliaryEntity.for.entity: 'C_ChgRecdObjPgMaintTskList'

define view N_ChgRecdObjPgMaintTskList
  as select from           I_ChgRecdRefMaintTskListBsc as ReferenceMaintTskListBsc
    left outer to one join I_BillOfOperations          as ReferenceMaintTskList on  ReferenceMaintTskListBsc.ChgRecRefInternalKey1 = ReferenceMaintTskList.BillOfOperationsType
                                                                               and ReferenceMaintTskListBsc.ChgRecRefInternalKey2 = ReferenceMaintTskList.BillOfOperationsGroup
                                                                               and ReferenceMaintTskListBsc.ChgRecRefInternalKey3 = ReferenceMaintTskList.BillOfOperationsVariant

  association [1..1] to C_ChgRecdMaintTskListVH       as _RefMaintTskListVH        on  $projection.BillOfOperationsType    = _RefMaintTskListVH.BillOfOperationsType
                                                                                  and $projection.BillOfOperationsGroup   = _RefMaintTskListVH.BillOfOperationsGroup
                                                                                  and $projection.BillOfOperationsVariant = _RefMaintTskListVH.BillOfOperationsVariant
  association [1..1] to I_ChangeRecordDraftTP         as _ChangeRecordTP          on  $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefMaintTskListBsc   as _RefMaintTskListExtension on  $projection.ChangeRecordReferenceUUID = _RefMaintTskListExtension.ChangeRecordReferenceUUID
  association [1..1] to C_ChgRecdItmRelMaintTskListVH as _ChangeRecordItemRelVH   on  $projection.ChangeRecordItemRelevance              = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                                  and $projection.ChangeRecordType                       = _ChangeRecordItemRelVH.ChangeRecordType
                                                                                  and (
                                                                                     $projection.ChangeRecordReferenceType               = _ChangeRecordItemRelVH.ChangeRecordReferenceType
                                                                                     or _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
                                                                                   )
{

          @UI.hidden: true
          @ObjectModel.readOnly: true
  key     ReferenceMaintTskListBsc.ChangeRecordReferenceUUID,
          @UI.lineItem:[{
                position:10,
                   label: 'Group',
                importance:#HIGH }
              ]
          @UI.identification: [{position: 10, importance: #HIGH}]
          @Consumption.valueHelp: '_RefMaintTskListVH'
          @ObjectModel.mandatory: true
          @Search.defaultSearchElement: true
          cast(ReferenceMaintTskList.BillOfOperationsGroup as r_plnnr preserving type)   as BillOfOperationsGroup,
          @UI.hidden: true
          ReferenceMaintTskList.BillOfOperationsType                                     as BillOfOperationsType,
          @UI.lineItem:[{
               position:25,
               label: 'Group Counter ',
               importance:#HIGH }
             ]
          @UI.identification: [{position: 30, importance: #HIGH }]
          cast(ReferenceMaintTskList.BillOfOperationsVariant as r_plnal preserving type) as BillOfOperationsVariant,
          ReferenceMaintTskListBsc. ChangeRecordItemProcgStatus,

          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordTP.ChangeRecordType                                              as ChangeRecordType,

          @UI.hidden: true
          ReferenceMaintTskListBsc.ChangeRecordUUID,
          @UI.hidden: true
          ReferenceMaintTskListBsc. ChangeRecordReferenceType,
          @UI.hidden: true
          ReferenceMaintTskListBsc. ParentChangeRecordRefUUID,
          @UI.lineItem:[{
                      position:35,
                      importance:#HIGH }
                    ]
          @UI.identification: [{position:50, importance: #HIGH}]
          ReferenceMaintTskListBsc.ChangeRecordItemRelevance,
          _ChangeRecordTP.ChangeRecordLifecycleStatus                                   as ChangeRecordLifecycleStatus,

          @UI.hidden: true
          ReferenceMaintTskListBsc.ChangeRecordReference,

          @Semantics.user.createdBy: true
          ReferenceMaintTskListBsc.CreatedByUser,
          @UI.hidden: true
          ReferenceMaintTskListBsc.CreationDateTime,
          @UI.hidden: true
          ReferenceMaintTskListBsc.LastChangeDateTime,
          _ChangeRecordTP,
          _ChangeRecordItemRelVH,
          _RefMaintTskListVH
}