N_ChgRecdFuncLocTskList

@AbapCatalog.sqlViewName:'NCHGRCDOBJPGFTL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Auxillary view Func Loc Tsk List'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AbapCatalog.preserveKey:true
@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant']
}

@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass:  #CUSTOMIZING,
                          sizeCategory: #S}
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
@VDM.auxiliaryEntity.for.entity: 'C_ChgRecdFuncLocTskList'

define view N_ChgRecdFuncLocTskList
  as select from           I_ChgRecdFuncLocTskListBsc as ReferenceFuncLocBsc
    left outer to one join I_BillOfOperations         as ReferenceFuncLoc on  ReferenceFuncLocBsc.ChgRecRefInternalKey1 = ReferenceFuncLoc.BillOfOperationsType
                                                                          and ReferenceFuncLocBsc.ChgRecRefInternalKey2 = ReferenceFuncLoc.BillOfOperationsGroup
                                                                          and ReferenceFuncLocBsc.ChgRecRefInternalKey3 = ReferenceFuncLoc.BillOfOperationsVariant

  association [1..1] to C_ChgRecdFuncLocTskListVH  as _RefFuncLocVH          on  $projection.BillOfOperationsType    = _RefFuncLocVH.BillOfOperationsType
                                                                             and $projection.BillOfOperationsGroup   = _RefFuncLocVH.BillOfOperationsGroup
                                                                             and $projection.BillOfOperationsVariant = _RefFuncLocVH.BillOfOperationsVariant
  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecordTP        on  $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdFuncLocTskListBsc as _RefFuncLocExtension   on  $projection.ChangeRecordReferenceUUID = _RefFuncLocExtension.ChangeRecordReferenceUUID
  association [1..1] to C_ChgRecdRlvnceFuncLocVH   as _ChangeRecordItemRelVH on  $projection.ChangeRecordItemRelevance              = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                             and $projection.ChangeRecordType                       = _ChangeRecordItemRelVH.ChangeRecordType
                                                                             and (
                                                                                $projection.ChangeRecordReferenceType               = _ChangeRecordItemRelVH.ChangeRecordReferenceType
                                                                                or _ChangeRecordItemRelVH.ChangeRecordReferenceType = ' '
                                                                              )
{

          @UI.hidden: true
          @ObjectModel.readOnly: true
  key     ChangeRecordReferenceUUID,
          @UI.lineItem:[{
                position:10,
                   label: 'Group',
                importance:#HIGH }
              ]
          @UI.identification: {position: 10, importance: #HIGH}
          @Consumption.valueHelp: '_RefFuncLocVH'
          @ObjectModel.mandatory: true
          @Search.defaultSearchElement: true
          cast(BillOfOperationsGroup as r_plnnr preserving type)   as BillOfOperationsGroup,
          @UI.hidden: true
          BillOfOperationsType                                     as BillOfOperationsType,
          @UI.lineItem:[{
               position:25,
               label: 'Group Counter ',
               importance:#HIGH }
             ]
          @UI.identification: {position: 30, importance: #HIGH }
          cast(BillOfOperationsVariant as r_plnal preserving type) as BillOfOperationsVariant,
          ChangeRecordItemProcgStatus,

          @UI.hidden: true
          @ObjectModel.readOnly: true
          _ChangeRecordTP.ChangeRecordType                         as ChangeRecordType,

          @UI.hidden: true
          ChangeRecordUUID,
          @UI.hidden: true
          ChangeRecordReferenceType,
          @UI.hidden: true
          ParentChangeRecordRefUUID,
          @UI.lineItem:[{
                      position:35,
                      importance:#HIGH }
                    ]
          @UI.identification: {position:50, importance: #HIGH}
          ChangeRecordItemRelevance,
          _ChangeRecordTP.ChangeRecordLifecycleStatus              as ChangeRecordLifecycleStatus,

          @UI.hidden: true
          ChangeRecordReference,

          @Semantics.user.createdBy: true
          CreatedByUser,
          @UI.hidden: true
          CreationDateTime,
          @UI.hidden: true
          LastChangeDateTime,
          _ChangeRecordTP,
          _ChangeRecordItemRelVH,
          _RefFuncLocVH
}