N_CapacityRequirementItemCap

DDL: N_CAPACITYREQUIREMENTITEMCAP Type: view_entity Package: VDM_PP_CRP

Capacity Requirement Item Capacity Aux

N_CapacityRequirementItemCap is a CDS View that provides data about "Capacity Requirement Item Capacity Aux" in SAP S/4HANA. It reads from 3 data sources (I_WorkCenter, I_WorkCenterText, kbed) and exposes 14 fields with key fields CapacityRequirement, CapacityRequirementItem, CapacityRqmtItemCapacity. It has 3 associations to related views. Part of development package VDM_PP_CRP.

3 data source(s) 14 fields

Data Sources (3)

SourceAliasJoin Type
I_WorkCenter _WorkCenter left_outer
I_WorkCenterText _WorkCenterText left_outer
kbed kbed from

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_CapacityRequirement _CapacityRequirement $projection.CapacityRequirement = _CapacityRequirement.CapacityRequirement
[1..1] I_CapacityRequirementItem _CapacityRequirementItem $projection.CapacityRequirement = _CapacityRequirementItem.CapacityRequirement and $projection.CapacityRequirementItem = _CapacityRequirementItem.CapacityRequirementItem
[1..1] I_WorkCenterType _WorkCenterType $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #REQUIRED view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.representativeKey CapacityRqmtItemCapacity view
Analytics.technicalName NPPCAPRQMTITMCAP view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.auxiliaryEntity.for.entity I_CapacityRequirementItemCap view
EndUserText.label Capacity Requirement Item Capacity Aux view

Fields (14)

KeyFieldSource TableSource FieldDescription
KEY CapacityRequirement kbed bedid
KEY CapacityRequirementItem
KEY CapacityRqmtItemCapacity
WorkCenterInternalID kbed arbid
WorkCenterTypeCode
PlannedOrder kbed plnum
OrderInternalID
WorkCenter I_WorkCenter WorkCenter
WorkCenterText I_WorkCenterText WorkCenterText
Plant I_WorkCenter Plant
WorkCenterCategoryCode I_WorkCenter WorkCenterCategoryCode
_CapacityRequirement _CapacityRequirement
_CapacityRequirementItem _CapacityRequirementItem
_WorkCenterType _WorkCenterType 
@AccessControl.authorizationCheck: #CHECK
//@Analytics.dataCategory: #DIMENSION

@AccessControl.personalData.blocking: #REQUIRED
@Metadata.ignorePropagatedAnnotations: true 
@ObjectModel.representativeKey: 'CapacityRqmtItemCapacity'
@Analytics.technicalName: 'NPPCAPRQMTITMCAP'
@ObjectModel.semanticKey: ['CapacityRequirement', 'CapacityRequirementItem', 'CapacityRqmtItemCapacity']
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.auxiliaryEntity.for.entity: 'I_CapacityRequirementItemCap'
@VDM.auxiliaryEntity.usage.type: [#ENTERPRISE_SEARCH]
//@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API

//@VDM.viewType: #BASIC

@EndUserText.label: 'Capacity Requirement Item Capacity Aux'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK", "CARDINALITY_CHECK" ]  } */
define view entity N_CapacityRequirementItemCap
  as select from    kbed   as kbed
  left outer join I_WorkCenter as _WorkCenter on  _WorkCenter.WorkCenterTypeCode = 'A' and _WorkCenter.WorkCenterInternalID = kbed.arbid
  left outer join I_WorkCenterText as _WorkCenterText on  _WorkCenterText.WorkCenterTypeCode = 'A' and _WorkCenterText.WorkCenterInternalID = kbed.arbid 
                                                      and _WorkCenterText.Language = $session.system_language
  association [1..1] to I_CapacityRequirement          as _CapacityRequirement          on  $projection.CapacityRequirement = _CapacityRequirement.CapacityRequirement
  association [1..1] to I_CapacityRequirementItem      as _CapacityRequirementItem      on  $projection.CapacityRequirement     = _CapacityRequirementItem.CapacityRequirement
                                                                                        and $projection.CapacityRequirementItem = _CapacityRequirementItem.CapacityRequirementItem
  association [1..1] to I_WorkCenterType               as _WorkCenterType               on  $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode

{
      // Key

      @ObjectModel.foreignKey.association: '_CapacityRequirement'
  key kbed.bedid as CapacityRequirement,
      @ObjectModel.foreignKey.association: '_CapacityRequirementItem'
  key cast(kbed.bedzl as pph_bedzl preserving type) as CapacityRequirementItem,
  key cast(kbed.canum as pph_canum preserving type) as CapacityRqmtItemCapacity,

//      @ObjectModel.foreignKey.association: '_WorkCenter'

      kbed.arbid as WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      'A' as WorkCenterTypeCode,
      kbed.plnum as PlannedOrder,      
      cast(kbed.aufpl as pph_aufpl preserving type)           as OrderInternalID,
//      _WorkCenter.WorkCenter,

      _WorkCenter.WorkCenter,
      _WorkCenterText.WorkCenterText,
      _WorkCenter.Plant,
      _WorkCenter.WorkCenterCategoryCode,
      // Associations

      _CapacityRequirement,
      _CapacityRequirementItem,
//      @Consumption.hidden: true

//      _WorkCenter,

      _WorkCenterType
//      _WorkCenterText


};

Learn More