N_CADocumentBPItem

DDL: N_CADOCUMENTBPITEM Type: view_entity Package: FKK_ESH

Document Business Partner Item

N_CADocumentBPItem is a CDS View that provides data about "Document Business Partner Item" in SAP S/4HANA. It reads from 1 data source (I_CADocumentBPItem) and exposes 29 fields with key fields CADocumentNumber, CARepetitionItemNumber, CABPItemNumber, CASubItemNumber. Part of development package FKK_ESH.

1 data source(s) 29 fields

Data Sources (1)

SourceAliasJoin Type
I_CADocumentBPItem I_CADocumentBPItem from

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label Document Business Partner Item view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.modelingPattern #NONE view
ObjectModel.sapObjectNodeType.name ContrAcctgDocumentBusPartItem view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XXL view
VDM.auxiliaryEntity.for.entity I_CADocumentBPItem view

Fields (29)

KeyFieldSource TableSource FieldDescription
KEY CADocumentNumber CADocumentNumber
KEY CARepetitionItemNumber CARepetitionItemNumber
KEY CABPItemNumber CABPItemNumber
KEY CASubItemNumber CASubItemNumber
CompanyCode CompanyCode
BusinessArea BusinessArea
Segment Segment
BusinessPartner BusinessPartner
CAProviderContract CAContract
ContractAccount ContractAccount
CAMainTransaction CAMainTransaction
CASubTransaction CASubTransaction
CADocumentOriginCode CADocumentOriginCode
CAPostingDate CAPostingDate
CANetDueDate CANetDueDate
TransactionCurrency TransactionCurrency
CAAmountInTransactionCurrency CAAmountInTransactionCurrency
CAClearingDocumentNumber CAClearingDocumentNumber
CAClearingReason CAClearingReason
CompanyCodeName _CompanyCode CompanyCodeName
CAProviderContractName _CAProviderContract CAProviderContractName
ContractAccountName _ContractAccount ContractAccountName
CAMainTransactionName
CASubTransactionName
TransactionCurrencyName
CAClearingReasonName
IsBusinessPurposeCompleted _BusinessPartner IsBusinessPurposeCompleted
CAAuthorizationGroup _ContractAccountPartner CAAuthorizationGroup
CAProviderContractAuthznGroup _CAProviderContract CAAuthorizationGroup 
@AbapCatalog.viewEnhancementCategory: [#NONE]

@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData: { blocking: #REQUIRED,
                                  blockingIndicator: ['IsBusinessPurposeCompleted'] } }

@EndUserText.label: 'Document Business Partner Item'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { modelingPattern: #NONE,
                sapObjectNodeType.name: 'ContrAcctgDocumentBusPartItem',
                usageType: { dataClass: #MIXED,
                             serviceQuality: #C,
                             sizeCategory: #XXL } }

@VDM: { auxiliaryEntity:{ for.entity: 'I_CADocumentBPItem',
                          usage.type: [#ENTERPRISE_SEARCH] } }

define view entity N_CADocumentBPItem
  as select from I_CADocumentBPItem

{
  key CADocumentNumber,
  key CARepetitionItemNumber,
  key CABPItemNumber,
  key CASubItemNumber,

      CompanyCode,
      BusinessArea,
      Segment,
      BusinessPartner,
      CAContract                                                                      as CAProviderContract,
      ContractAccount,
      CAMainTransaction,
      CASubTransaction,
      CADocumentOriginCode,
      CAPostingDate,
      CANetDueDate,
      TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CAAmountInTransactionCurrency,
      CAClearingDocumentNumber,
      CAClearingReason,

      /* additional data */
      _CompanyCode.CompanyCodeName,
      _CAProviderContract.CAProviderContractName,
      _ContractAccount.ContractAccountName,
      _CAMainTransaction._Text[1: Language = $session.system_language].CAMainTransactionName,
      _CASubTransaction._Text[1: Language = $session.system_language].CASubTransactionName,
      _TransactionCurrency._Text[1: Language = $session.system_language].CurrencyName as TransactionCurrencyName,
      _CAClearingReason._Text[1: Language = $session.system_language].CAClearingReasonName,

      /* additional data for authorization checks */
      @Semantics.booleanIndicator
      _BusinessPartner.IsBusinessPurposeCompleted,
      _ContractAccountPartner.CAAuthorizationGroup,
      _CAProviderContract.CAAuthorizationGroup                                        as CAProviderContractAuthznGroup
}

Learn More