N_CAContractPartner

DDL: N_CACONTRACTPARTNER Type: view_entity Package: FKK_ESH

Contract Partner

N_CAContractPartner is a CDS View that provides data about "Contract Partner" in SAP S/4HANA. It reads from 1 data source (I_CAContractPartner) and exposes 31 fields with key field BusinessPartner. It has 1 association to related views. Part of development package FKK_ESH.

1 data source(s) 31 fields

Data Sources (1)

SourceAliasJoin Type
I_CAContractPartner I_CAContractPartner from

Associations (1)

CardinalityTargetAliasCondition
[0..*] dd07t _BusinessPartnerCategory $projection.BusinessPartnerCategory = _BusinessPartnerCategory.domvalue_l and _BusinessPartnerCategory.domname = 'BU_TYPE'

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label Contract Partner view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.modelingPattern #NONE view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
VDM.auxiliaryEntity.for.entity I_CAContractPartner view

Fields (31)

KeyFieldSource TableSource FieldDescription
KEY BusinessPartner BusinessPartner
FormOfAddress FormOfAddress
BusinessPartnerCategory BusinessPartnerCategory
FormOfAddressName
BusinessPartnerCategoryText
FirstName _BusinessPartner FirstName
LastName _BusinessPartner LastName
OrganizationBPName1 _BusinessPartner OrganizationBPName1
OrganizationBPName2 _BusinessPartner OrganizationBPName2
SearchTerm1 _BusinessPartner SearchTerm1
SearchTerm2 _BusinessPartner SearchTerm2
StreetName
HouseNumber
PostalCode
CityName
Region
Country
BusinessPartnerRole BusinessPartnerRole
AuthorizationGroup AuthorizationGroup
DataController1 _BusinessPartner DataController1
DataController2 _BusinessPartner DataController2
DataController3 _BusinessPartner DataController3
DataController4 _BusinessPartner DataController4
DataController5 _BusinessPartner DataController5
DataController6 _BusinessPartner DataController6
DataController7 _BusinessPartner DataController7
DataController8 _BusinessPartner DataController8
DataController9 _BusinessPartner DataController9
DataController10 _BusinessPartner DataController10
DataControllerSet _BusinessPartner DataControllerSet
IsBusinessPurposeCompleted _BusinessPartner IsBusinessPurposeCompleted 
@AbapCatalog.viewEnhancementCategory: [#NONE]

@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData: { blocking: #REQUIRED,
                                  blockingIndicator: ['IsBusinessPurposeCompleted'] } }

@EndUserText.label: 'Contract Partner'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: { modelingPattern: #NONE,
                usageType: { dataClass: #MIXED,
                             serviceQuality: #C,
                             sizeCategory: #XL } }

@VDM: { auxiliaryEntity:{ for.entity: 'I_CAContractPartner',
                          usage.type: [#ENTERPRISE_SEARCH] } }

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view entity N_CAContractPartner
  as select from I_CAContractPartner

  // there is no auxiliary view for the I_BusPartCategoryText so far

  association [0..*] to dd07t as _BusinessPartnerCategory on  $projection.BusinessPartnerCategory = _BusinessPartnerCategory.domvalue_l
                                                          and _BusinessPartnerCategory.domname    = 'BU_TYPE'

{
  key BusinessPartner,

      FormOfAddress,
      BusinessPartnerCategory,

      /* additional data */
      _FormOfAddress._Text[1:Language = $session.system_language].FormOfAddressName,
      _BusinessPartnerCategory[1: ddlanguage = $session.system_language].ddtext as BusinessPartnerCategoryText,

      _BusinessPartner.FirstName,
      _BusinessPartner.LastName,
      _BusinessPartner.OrganizationBPName1,
      _BusinessPartner.OrganizationBPName2,
      _BusinessPartner.SearchTerm1,
      _BusinessPartner.SearchTerm2,

      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.StreetName,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.HouseNumber,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.PostalCode,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.CityName,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.Region,
      _BusinessPartner._CurrentDefaultAddress._AddressDefaultRepresentation.Country,

      /* additional data for authorization checks */
      BusinessPartnerRole,
      AuthorizationGroup,
      _BusinessPartner.DataController1,
      _BusinessPartner.DataController2,
      _BusinessPartner.DataController3,
      _BusinessPartner.DataController4,
      _BusinessPartner.DataController5,
      _BusinessPartner.DataController6,
      _BusinessPartner.DataController7,
      _BusinessPartner.DataController8,
      _BusinessPartner.DataController9,
      _BusinessPartner.DataController10,
      _BusinessPartner.DataControllerSet,
      @Semantics.booleanIndicator 
      _BusinessPartner.IsBusinessPurposeCompleted
}

Learn More