I_WorkAssgmtWorkOrderDEX

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Assignment Work Order Details'

@VDM.viewType: #COMPOSITE
@Analytics.dataExtraction: {
            enabled: true,
            delta.changeDataCapture:
              {
              mapping:[
               {
                table: 'BUT050',
                role:#MAIN,
                viewElement: [ 'RelationshipNumber', 'Supplier','BusinessPartner2','EndDate'],
                tableElement: [ 'relnr','partner1','partner2','date_to' ]
               },
               {
                table: 'WFD_D_KEYMAP',
                role: #LEFT_OUTER_TO_ONE_JOIN,
                viewElement: [ 'WorkAssignment'],
                tableElement: [ 'workforce_assgmt_id' ]
               }
              
              ]
                
              }
            
        }
  

@ObjectModel.supportedCapabilities:[ #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.sapObjectNodeType.name:'WorkOrderDetails'
@Metadata.ignorePropagatedAnnotations:true 



define view entity I_WorkAssgmtWorkOrderDEX   as select distinct from I_WorkAssignmentKeyMapping as Assignment
    inner join   I_WorkAssignmentBP         as AssignmentBP   on  AssignmentBP.WorkAssignment   = Assignment.WorkAssignment
                                                               and Assignment.IsContingentWorker = 'X'

    inner join   I_BPRelationship_2         as BPRelationship on BPRelationship.BusinessPartner2 = AssignmentBP.WorkAssignmentBusinessPartner
    
    

  association [0..1] to I_WorkAssignmentDEX_1  as _WorkAssignment  on  _WorkAssignment.WorkAssignmentExternalID = $projection.WorkAssignmentExternalID

  association [1]    to I_WorkforcePersonDEX_1 as _WorkforcePerson on  _WorkforcePerson.WorkforcePersonExternalID = $projection.WorkforcePersonExternalID

{
  key BPRelationship.RelationshipNumber ,
  
  key BPRelationship.BusinessPartner1 as Supplier,
  
  key BPRelationship.BusinessPartner2 ,
  
  key BPRelationship.ValidityEndDate as EndDate,

      BPRelationship.ValidityStartDate as StartDate,
      
      Assignment.WorkAssignment,
            
      AssignmentBP.WorkforcePersonExternalID,
      Assignment.WorkAssignmentExternalID,
      Assignment.Country2DigitISOCode,
      
      @Semantics.booleanIndicator: true
      @UI.hidden: true
      Assignment.IsBlocked,

      /* Associations */
      _WorkAssignment,
      _WorkforcePerson

}
where
  (
      BPRelationship.RelationshipCategory = 'HCM003'
    or(
      BPRelationship.RelationshipCategory = 'BUR025'
    )
  )

  and Assignment.IsContingentWorker       = 'X'