I_WorkAssgmtAddressDEX

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@EndUserText.label: 'Work Assignment Address Details'

@VDM.viewType: #COMPOSITE
@Analytics.dataExtraction: {
            enabled: true,
            delta.changeDataCapture:
    {
            mapping:[
                  {
                    table: 'but020',
                    role: #MAIN,
                    viewElement: ['WorkAssignmentBusinessPartner','AddressNumber'],
                    tableElement: ['Partner','addrnumber']
                }
            ]
        }
    }
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.supportedCapabilities:[ #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER 
@ObjectModel.sapObjectNodeType.name:'AddressDetails'
@Consumption.dbHints:[ 'USE_HEX_PLAN' ]

define view entity I_WorkAssgmtAddressDEX
  as select from I_WorkAssignmentKeyMapping as Assignment

    inner join   I_WorkAssignmentBP         as AssignmentBP      on AssignmentBP.WorkAssignment = Assignment.WorkAssignment
    inner join   I_BusPartAddress           as EmploymentAddress on EmploymentAddress.BusinessPartner = AssignmentBP.WorkAssignmentBusinessPartner


  association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on  $projection.WorkAssignmentBusinessPartner = _BPProtectedAddress.BusinessPartner
                                                                    and $projection.AddressNumber   = _BPProtectedAddress.AddressID
  association [0..1] to I_WorkAssignmentDEX_1   as _WorkAssignment     on  _WorkAssignment.WorkAssignment = $projection.WorkAssignment
  association [1..1] to I_BusinessPartner    as _BusinessPartner    on  _BusinessPartner.BusinessPartner = $projection.WorkAssignmentBusinessPartner

  association [1]    to I_WorkforcePersonDEX_1  as _WorkforcePerson  on  _WorkforcePerson.WorkforcePersonExternalID = $projection.WorkforcePersonExternalID
{

     key EmploymentAddress.BusinessPartner as WorkAssignmentBusinessPartner,
     key EmploymentAddress.AddressID     as AddressNumber,  
          Assignment.WorkAssignment,
          Assignment.WorkAssignmentExternalID,
          Assignment.Country2DigitISOCode,
          AssignmentBP.WorkforcePersonExternalID,        
          cast (tstmp_to_dats( EmploymentAddress.ValidityStartDate,
          abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as vdm_v_start_date) as StartDate,
          cast (tstmp_to_dats( EmploymentAddress.ValidityEndDate,
            abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as vdm_v_end_date) as EndDate,
          EmploymentAddress._AddressDefaultRepresentation.Country,
          EmploymentAddress._AddressDefaultRepresentation.PostalCode,
          EmploymentAddress._AddressDefaultRepresentation.Region,
          EmploymentAddress._AddressDefaultRepresentation.SecondaryRegion,
          EmploymentAddress._AddressDefaultRepresentation.SecondaryRegionName,
          EmploymentAddress._AddressDefaultRepresentation.TertiaryRegion,
          EmploymentAddress._AddressDefaultRepresentation.TertiaryRegionName,
          EmploymentAddress._AddressDefaultRepresentation.CityName,
          EmploymentAddress._AddressDefaultRepresentation.DistrictName,
          EmploymentAddress._AddressDefaultRepresentation.StreetPrefixName1,
          EmploymentAddress._AddressDefaultRepresentation.StreetPrefixName2,
          EmploymentAddress._AddressDefaultRepresentation.StreetName,
          EmploymentAddress._AddressDefaultRepresentation.StreetSuffixName1,
          EmploymentAddress._AddressDefaultRepresentation.StreetSuffixName2,
          EmploymentAddress._AddressDefaultRepresentation.HouseNumber,
          EmploymentAddress._AddressDefaultRepresentation.HouseNumberSupplementText,
          EmploymentAddress._AddressDefaultRepresentation.Floor,
          EmploymentAddress._AddressDefaultRepresentation.RoomNumber,
          EmploymentAddress._AddressDefaultRepresentation.CareOfName,
          EmploymentAddress._AddressDefaultRepresentation.POBoxPostalCode,

          @Semantics.booleanIndicator: true
          @UI.hidden: true
          Assignment.IsBlocked,
          @Semantics.booleanIndicator: true
          @UI.hidden: true
          @Consumption.hidden: true
          _BusinessPartner.IsBusinessPurposeCompleted,
          @Consumption.hidden:true
          @UI.hidden:true          
          _BusinessPartner.DataControllerSet,
          _BusinessPartner.AuthorizationGroup,

          /* Associations */
          //_BPProtectedAddress,

          _BPProtectedAddress,
          _BusinessPartner,
          _WorkAssignment,
          _WorkforcePerson
          

}