I_WellCompletion

@EndUserText.label: 'Well Completion'
@Analytics.dataCategory: #DIMENSION
@Metadata.allowExtensions:true
@Analytics.dataExtraction.enabled: true
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IPVWELLCOMPLTN'
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.representativeKey: 'WellCompletion'
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET,
                                     #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.sapObjectNodeType.name: 'PRAWellCompletion'
@Metadata.ignorePropagatedAnnotations:true 

@Search.searchable: true
define view I_WellCompletion
  as select from oiu_pr_wc
  association [0..1] to I_Well                    as _Well                        on  $projection.Well = _Well.Well
  association [0..1] to I_DevelopmentProgramNmbr  as _DevelopmentProgramNmbr      on  $projection.DevelopmentProgramNmbr = _DevelopmentProgramNmbr.DevelopmentProgramNmbr
  association [0..1] to I_WellPurpose             as _WellPurpose                 on  $projection.WellPurpose = _WellPurpose.WellPurpose
  association [0..1] to I_WellCompletionHier      as _WellCompletionHier          on  $projection.WellCompletionHier = _WellCompletionHier.WellCompletionHier
  association [0..1] to I_Country                 as _Country                     on  $projection.Country = _Country.Country
  association [0..1] to I_PrimaryGeogrlLocation   as _PrimaryGeogrlLocation       on  $projection.Country               = _PrimaryGeogrlLocation.Country
                                                                                  and $projection.PrimaryGeogrlLocation = _PrimaryGeogrlLocation.PrimaryGeogrlLocation
  association [0..1] to I_SecondaryGeogrlLocation as _SecondaryGeogrlLocation     on  $projection.Country                 = _SecondaryGeogrlLocation.Country
                                                                                  and $projection.PrimaryGeogrlLocation   = _SecondaryGeogrlLocation.PrimaryGeogrlLocation
                                                                                  and $projection.SecondaryGeogrlLocation = _SecondaryGeogrlLocation.SecondaryGeogrlLocation
  association [0..1] to I_OffshorePlatform        as _OffshorePlatform            on  $projection.OffshorePlatform = _OffshorePlatform.OffshorePlatform
  association [0..1] to I_Reservoir               as _Reservoir                   on  $projection.Reservoir = _Reservoir.Reservoir
  association [0..1] to I_ReservoirZone           as _ReservoirZone               on  $projection.Reservoir     = _ReservoirZone.Reservoir
                                                                                  and $projection.ReservoirZone = _ReservoirZone.ReservoirZone
  association [0..1] to I_GeologicField           as _GeologicField               on  $projection.GeologicField = _GeologicField.GeologicField
  association [0..1] to I_OrganizationalUnit      as _OrganizationalUnit          on  $projection.OrganizationalUnit = _OrganizationalUnit.OrganizationalUnit
  association [0..1] to I_OrganizationalUnit2     as _OrganizationalUnit2         on  $projection.OrganizationalUnit  = _OrganizationalUnit2.OrganizationalUnit
                                                                                  and $projection.OrganizationalUnit2 = _OrganizationalUnit2.OrganizationalUnit2
  association [0..1] to I_OrganizationalUnit3     as _OrganizationalUnit3         on  $projection.OrganizationalUnit  = _OrganizationalUnit3.OrganizationalUnit
                                                                                  and $projection.OrganizationalUnit2 = _OrganizationalUnit3.OrganizationalUnit2
                                                                                  and $projection.OrganizationalUnit3 = _OrganizationalUnit3.OrganizationalUnit3
  association [0..1] to I_OrganizationalUnit4     as _OrganizationalUnit4         on  $projection.OrganizationalUnit  = _OrganizationalUnit4.OrganizationalUnit
                                                                                  and $projection.OrganizationalUnit2 = _OrganizationalUnit4.OrganizationalUnit2
                                                                                  and $projection.OrganizationalUnit3 = _OrganizationalUnit4.OrganizationalUnit3
                                                                                  and $projection.OrganizationalUnit4 = _OrganizationalUnit4.OrganizationalUnit4
  association [0..1] to I_User                    as _CreatedByUser               on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_Indicator               as _CoalBedMethaneRptgIsEnabled on  $projection.CoalBedMethaneRptgIsEnabled = _CoalBedMethaneRptgIsEnabled.IndicatorValue
{
      @ObjectModel.foreignKey.association: '_Well'
  key wl_no                                                                      as Well,
      @ObjectModel.text.element:  [ 'WellCompletionName' ]
      @Search                         : {ranking: #HIGH, defaultSearchElement: true, fuzzinessThreshold: 0.8}      
  key wc_no                                                                      as WellCompletion,
      @Semantics.text: true
      @EndUserText.label: 'Well Completion Name'
      cast (name as oiu_wc_nm preserving type)                                   as WellCompletionName,
      api_wc_no                                                                  as APIWellCompletionNumber,
      @ObjectModel.foreignKey.association: '_DevelopmentProgramNmbr'
      dev_pgm_no                                                                 as DevelopmentProgramNmbr,
      cast ( 'DEG' as oiu_uom )   as LatitudeUnit,    
      @Semantics.quantity.unitOfMeasure: 'LatitudeUnit'      
      lat_no                                                                     as WellCompletionLatitude,
      lat_dir_cd                                                                 as WellCompltnLatitudeDirection,
      cast ( 'DEG' as oiu_uom )   as LongitudeUnit, 
      @Semantics.quantity.unitOfMeasure: 'LongitudeUnit'      
      lng_no                                                                     as WellCompletionLongitude,
      lng_dir_cd                                                                 as WellCompltnLongitudeDirection,
      @ObjectModel.foreignKey.association: '_Country'
      @Semantics.address.country: true
      cast( cntry_cd as land1_gp )                                               as Country,
      @ObjectModel.foreignKey.association: '_PrimaryGeogrlLocation'
      @Semantics.address.region: true
      pri_geo_loc                                                                as PrimaryGeogrlLocation,
      @ObjectModel.foreignKey.association: '_SecondaryGeogrlLocation'
      @Semantics.address.subRegion: true
      sec_geo_loc                                                                as SecondaryGeogrlLocation,
      @ObjectModel.foreignKey.association: '_OffshorePlatform'
      pf_no                                                                      as OffshorePlatform,
      @ObjectModel.foreignKey.association: '_Reservoir'
      resrv                                                                      as Reservoir,
      @ObjectModel.foreignKey.association: '_ReservoirZone'
      reszn                                                                      as ReservoirZone,
      @ObjectModel.foreignKey.association: '_GeologicField'
      field                                                                      as GeologicField,
      @ObjectModel.foreignKey.association: '_WellPurpose'
      pur_cd                                                                     as WellPurpose,
      alt_wc_key                                                                 as AlternateWellCompletionKey,
      @ObjectModel.foreignKey.association: '_WellCompletionHier'
      wc_set                                                                     as WellCompletionHier,
      @ObjectModel.foreignKey.association: '_OrganizationalUnit'
      or1_or_lvl_1_no                                                            as OrganizationalUnit,
      @ObjectModel.foreignKey.association: '_OrganizationalUnit2'
      or2_or_lvl_2_no                                                            as OrganizationalUnit2,
      @ObjectModel.foreignKey.association: '_OrganizationalUnit3'
      or3_or_lvl_3_no                                                            as OrganizationalUnit3,
      @ObjectModel.foreignKey.association: '_OrganizationalUnit4'
      or4_or_lvl_4_no                                                            as OrganizationalUnit4,
      @ObjectModel.foreignKey.association: '_CoalBedMethaneRptgIsEnabled'
      cbm_indicator                                                              as CoalBedMethaneRptgIsEnabled,

      //adminstrative

      @Semantics.user.createdBy: true
      cast( oiu_cruser as fclm_bam_created_by )                                  as CreatedByUser,
      cast( oiu_timestamp as oiu_vdm_created_on_ts )                             as CreationDateTime,

      _Well,
      _DevelopmentProgramNmbr,
      _WellPurpose,
      _WellCompletionHier,
      _Country,
      _PrimaryGeogrlLocation,
      _SecondaryGeogrlLocation,
      _OffshorePlatform,
      _Reservoir,
      _ReservoirZone,
      _GeologicField,
      _CoalBedMethaneRptgIsEnabled,
      _OrganizationalUnit,
      _OrganizationalUnit2,
      _OrganizationalUnit3,
      _OrganizationalUnit4,
      _CreatedByUser
};