I_WBSElementWithCodingMask

@AbapCatalog.sqlViewName: 'IWBSELECODEMSK'
@EndUserText.label: 'WBS Element Data'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
@ObjectModel.usageType.dataClass: #MASTER
@Analytics.dataCategory: #DIMENSION
@Metadata.allowExtensions: true
@Analytics.internalName: #LOCAL
@ObjectModel.representativeKey: 'WBSElementExternalID'
@VDM.viewType: #COMPOSITE
@Search.searchable: true
@Consumption.ranked: true
@AbapCatalog.preserveKey:true

define view I_WBSElementWithCodingMask
  as select from I_WBSElementData_2
  association [0..1] to I_ProjectResponsiblePerson as _ResponsiblePerson on $projection.ResponsiblePerson = _ResponsiblePerson.ResponsiblePerson
  association [0..1] to I_ProjectApplicant         as _ProjectApplicant  on $projection.ApplicantCode = _ProjectApplicant.ApplicantCode
{
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }        
  key WBSElementExternalID          as WBSElementExternalID,
      @UI:{ hidden: true }
      WBSElementInternalID          as WBSElementInternalID,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      WBSDescription                as WBSDescription,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      I_WBSElementData_2._WBSElementShortText.LanguageBasedShortText as WBSElementLangBsdDescription,
      _Project.ProjectExternalID    as ProjectExternalID,
      _Project.ProjectDescription   as ProjectDescription,
      ResponsiblePerson             as ResponsiblePerson,
      ResponsiblePersonName         as ResponsiblePersonName,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSElementIsBillingElement    as WBSElementIsBillingElement,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSIsAccountAssignmentElement as WBSIsAccountAssignmentElement,
      @Consumption.filter: {selectionType: #SINGLE , multipleSelections: false }
      WBSElementIsPlanningElement   as WBSElementIsPlanningElement,
      @UI:{ hidden: true }
      WBSElementHierarchyLevel      as WBSElementHierarchyLevel,

      @UI:{ hidden: true }
      ProjectType                   as ProjectType,
      @UI:{ hidden: true }
      ControllingArea               as ControllingArea,
      @UI:{ hidden: true }
      RespCostCenterControllingArea as RespCostCenterControllingArea,
      @UI:{ hidden: true }
      ResponsibleCostCenter         as ResponsibleCostCenter,
      @UI:{ hidden: true }
      ProfitCenter                  as ProfitCenter,
      @UI:{ hidden: true }
      FreeDefinedAttribute01        as FreeDefinedAttribute01,
      @UI:{ hidden: true }
      FreeDefinedAttribute02        as FreeDefinedAttribute02,
      @UI:{ hidden: true }
      FreeDefinedAttribute03        as FreeDefinedAttribute03,
      @UI:{ hidden: true }
      FreeDefinedAttribute04        as FreeDefinedAttribute04,
      @UI:{ hidden: true }
      FreeDefinedIndicator1         as FreeDefinedIndicator1,
      @UI:{ hidden: true }
      FreeDefinedIndicator2         as FreeDefinedIndicator2,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      ApplicantCode                 as ApplicantCode,
      @UI:{ hidden: true }
      WBSElementObject              as WBSElementObject,
      @UI:{ hidden: true }
      _Project.ProjectObject        as ProjectObject,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      _ResponsiblePerson,
      @UI:{ hidden: true }
      @Consumption.hidden: true
      _ProjectApplicant
}