I_UsageDcsnSelectedCodeSet

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Selected Set of Codes for Usage Decision'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.usageType: {
    dataClass: #MASTER,
    sizeCategory: #M,
    serviceQuality: #A 
}
@ObjectModel.representativeKey: 'SelectedCodeSet'
@Analytics.technicalName: 'IUDSELCODESET'
@Metadata.ignorePropagatedAnnotations: true
define view entity I_UsageDcsnSelectedCodeSet as select from qpam

   association [0..1] to I_Plant as _SelectedCodeSetPlant
      on $projection.SelectedCodeSetPlant = _SelectedCodeSetPlant.Plant
      
   association [0..*] to I_UsageDcsnSelectedCodeSetTxt as _Text
      on  $projection.SelectedCodeSetPlant = _Text.SelectedCodeSetPlant
      and $projection.SelectedCodeSet      = _Text.SelectedCodeSet
      
   association [0..*] to I_UsgeDcsnSelectedSetCodeGrp as _UsgeDcsnSelectedSetCodeGrp 
      on $projection.SelectedCodeSetPlant = _UsgeDcsnSelectedSetCodeGrp.SelectedCodeSetPlant
      and $projection.SelectedCodeSet     = _UsgeDcsnSelectedSetCodeGrp.SelectedCodeSet
{
    @ObjectModel.foreignKey.association: '_SelectedCodeSetPlant'
    key qpam.werks                as SelectedCodeSetPlant,
    @ObjectModel.text.association: '_Text'
    key qpam.auswahlmge           as SelectedCodeSet,

//    qpam.ltextv, 

//    qpam.ersteller, 

//    qpam.e_datum, 

//    qpam.aenderer, 

//    qpam.a_datum, 

//    qpam.verwendung, 

    @UI.hidden: true // At the moment we do not have a proper VDM model for the domain QLOESCHKZ1 => hide this field on UIs

    qpam.status                   as InspectionSelectedSetStatus,
    qpam.defaultcodegr            as SelectedCodeSetDfltCodeGroup,
    qpam.defaultcode              as SelectedCodeSetDefaultCode,
    
    @Semantics.user.createdBy: true
    qpam.ersteller      as UsgeDcsnSeldSetCreatedBy,
    @Semantics.systemDateTime.createdAt: true
    qpam.e_datum        as UsgeDcsnSeldSetCreatedOn,
    @Semantics.user.lastChangedBy: true
    qpam.aenderer       as UsgeDcsnSeldSetLastChgdBy,
    @Semantics.systemDate.lastChangedAt: true
    qpam.a_datum        as UsgeDcsnSeldSetLastChangedOn,    
    
    /* Associations */
    _SelectedCodeSetPlant,
    _UsgeDcsnSelectedSetCodeGrp,
    _Text
    
} where qpam.katalogart = '3'