I_USER_F4

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'SUIM Simple Value Help for Dialog Users'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
//----------------------------------------------------------------------

// SUIM view to get a simple value help list with

// valid dialog users (user with dialog logon)

// - authority check against S_USER_GRP ( ACTVT 03/F4, CLASS) 

// - ask the owner before reuse

//----------------------------------------------------------------------

define view entity I_USER_F4
  as select from           SUIM_USER_VALID_STATE as usr02
    inner join             usr21     on usr02.bname = usr21.bname
    left outer to one join adrp      on  usr21.persnumber = adrp.persnumber
                                     and adrp.nation      = ''
                                     and adrp.date_from   = '00010101'
    left outer to one join adcp      on  usr21.persnumber = adcp.persnumber
                                     and usr21.addrnumber = adcp.addrnumber
                                     and adcp.nation      = ''
                                     and adcp.date_from   = '00010101'
    left outer to one join uscompany on usr21.addrnumber       = uscompany.addrnumber
                                     or usr21.template_orgaddr = uscompany.addrnumber // Use company or template_company

{
  key usr02.bname       as bname,

      @Consumption.hidden: true
      usr02.class       as Class,

      adrp.name_first   as GivenName,
      adrp.name_last    as FamilyName,
      adcp.ih_mail      as InhouseMail,
      adcp.department   as WorkplaceDepartmentName,
      adcp.function     as WorkplaceFunctionalTitleName,
      uscompany.company as company
}
where
      usr02.time_intv_valid = 'X'
  and usr02.user_unlocked   = 'X'
  and usr02.user_dia_type   = 'X'