I_TreasuryReferenceItem

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Treasury Reference Item Information'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #A,
    sizeCategory: #M
  },
  supportedCapabilities: [#ANALYTICAL_DIMENSION,  #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE , #EXTRACTION_DATA_SOURCE],
  modelingPattern: #ANALYTICAL_DIMENSION,
  representativeKey: 'TreasuryFinancialObject',
  sapObjectNodeType.name: 'TreasuryReferenceItem'
}
@Analytics: {
  dataCategory: #DIMENSION,
  internalName:#LOCAL,
  dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
        mapping:
        [
        {
            role: #MAIN,
            table: 'REFON',
            viewElement: [ 'TreasuryReferenceCategory', 'TreasuryReferenceNumber', 'TreasuryFinancialObject' ],
            tableElement: [ 'REFTYP', 'REFNR', 'OBJNR' ]
        },
        {
            role: #LEFT_OUTER_TO_ONE_JOIN,
            table: 'REFH',
            viewElement: [ 'TreasuryReferenceCategory', 'TreasuryReferenceNumber'],
            tableElement: [ 'REFTYP', 'REFNR' ]
        }
    ]
    }
  }
}
@Metadata.allowExtensions:true
@VDM.viewType: #BASIC
define view entity I_TreasuryReferenceItem
  as select from refon
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_FinancialTransaction      as _FinancialTransaction      on  $projection.TreasuryFinancialObject = _FinancialTransaction.TreasuryFinancialObject
  association [1..1] to I_TreasuryReferenceCategory as _TreasuryReferenceCategory on  $projection.TreasuryReferenceCategory = _TreasuryReferenceCategory.TreasuryReferenceCategory
  association [1..1] to I_TreasuryReference         as _TreasuryReference         on  $projection.TreasuryReferenceCategory = _TreasuryReference.TreasuryReferenceCategory
                                                                                  and $projection.TreasuryReferenceNumber   = _TreasuryReference.TreasuryReferenceNumber
{
      /* start suppress warning shlporigin_not_inherited */
      @ObjectModel.foreignKey.association: '_TreasuryReferenceCategory'
  key cast( reftyp as trsy_ref_cat preserving type )         as TreasuryReferenceCategory,
      @ObjectModel.foreignKey.association: '_TreasuryReference'
  key cast( refnr  as trsy_ref_nmbr preserving type )        as TreasuryReferenceNumber,
  key objnr                                                  as TreasuryFinancialObject,
      /* end suppress warning shlporigin_not_inherited */
      cast( status as trsy_ref_item_status preserving type ) as TreasuryReferenceItemStatus,
      cast( rrang as trsy_ref_item_ranking preserving type ) as TreasuryReferenceItemRanking,
      cast( cruser as trsy_ref_item_cruser preserving type ) as TrsyReferenceItemCreatedByUser,
      cast( dcrdat as trsy_ref_item_dcrdat preserving type ) as TrsyReferenceItemCreationDate,
      cast( tcrtim as trsy_ref_item_tcrtim preserving type ) as TrsyReferenceItemCreationTime,
      cast( upuser as trsy_ref_item_upuser preserving type ) as TrsyRefItemLastChangedByUser,
      cast( dupdat as trsy_ref_item_dupdat preserving type ) as TrsyRefItemLastChangeDate,
      cast( tuptim as trsy_ref_item_tuptim preserving type ) as TrsyRefItemLastChangeTime,
      _TreasuryReference.TreasuryReferenceStatus,

      _FinancialTransaction,
      _TreasuryReferenceCategory,
      _TreasuryReference
}