I_TranspOrdLifeCycStatusT_2

DDL: I_TRANSPORDLIFECYCSTATUST_2 Type: view_entity BASIC Package: VDM_TM_BASIC

Transp Order Lifecycle Status - Text

I_TranspOrdLifeCycStatusT_2 is a Basic CDS View that provides data about "Transp Order Lifecycle Status - Text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields TranspOrdLifeCycleStatus, Language. It has 1 association to related views. Part of development package VDM_TM_BASIC.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (12)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Transp Order Lifecycle Status - Text view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #TEXT view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.representativeKey TranspOrdLifeCycleStatus view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #META view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
VDM.viewType #BASIC view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY TranspOrdLifeCycleStatus
KEY Language ddlanguage
TranspOrdLifeCycleStatusDesc
DomainValue dd07t domvalue_l
_TranspOrdLifeCycleStatus _TranspOrdLifeCycleStatus
_Language _Language 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Transp Order Lifecycle Status - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'TranspOrdLifeCycleStatus'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
define view entity I_TranspOrdLifeCycStatusT_2
  as select from dd07t
  association        to parent I_TranspOrdLifeCycleStatus_2 as _TranspOrdLifeCycleStatus on $projection.TranspOrdLifeCycleStatus = _TranspOrdLifeCycleStatus.TranspOrdLifeCycleStatus
  association [0..1] to I_Language                          as _Language                 on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_TranspOrdLifeCycleStatus'
  key cast(substring(domvalue_l, 1, 2) as /scmtms/tor_lc_status preserving type) as TranspOrdLifeCycleStatus,

      @Semantics.language
      @ObjectModel.foreignKey.association: '_Language'
  key ddlanguage                                                                 as Language,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast(ddtext as /scmtms/vdm_tor_lc_status_desc preserving type )            as TranspOrdLifeCycleStatusDesc,

      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                                           as DomainValue,

      /* Associations */
      _TranspOrdLifeCycleStatus,
      _Language
}
where
      domname                     =  '/SCMTMS/TOR_LC_STATUS'
  and as4local                    =  'A'
  and substring(domvalue_l, 1, 2) <> '00' //Draft

  and substring(domvalue_l, 1, 2) <> '01' //New

Learn More