I_TimeSheetTaskAcctgCatTxt

DDL: I_TIMESHEETTASKACCTGCATTXT Type: view_entity BASIC Package: VDM_TIMESHEET_TASK

Timesheet Task Accounting Cat - Text

I_TimeSheetTaskAcctgCatTxt is a Basic CDS View that provides data about "Timesheet Task Accounting Cat - Text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields Language, TimeSheetTaskAccountingCat. It has 2 associations to related views. Part of development package VDM_TIMESHEET_TASK.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_TimeSheetTaskAccountingCat _AccountingCat $projection.TimeSheetTaskAccountingCat = _AccountingCat.TimeSheetTaskAccountingCat
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (12)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Timesheet Task Accounting Cat - Text view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.dataCategory #TEXT view
ObjectModel.modelingPattern #LANGUAGE_DEPENDENT_TEXT view
ObjectModel.representativeKey TimeSheetTaskAccountingCat view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #META view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
VDM.viewType #BASIC view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Language
KEY TimeSheetTaskAccountingCat
DomainValue dd07t domvalue_l
TimeSheetTaskAccountingCatName
_AccountingCat _AccountingCat
_Language _Language 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Timesheet Task Accounting Cat - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  representativeKey: 'TimeSheetTaskAccountingCat',
  supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SEARCHABLE_ENTITY,
                                     #SQL_DATA_SOURCE],
  usageType: {
    serviceQuality: #A,
    dataClass: #META,
    sizeCategory: #S
  }
}  
@Search.searchable: true
@VDM: {
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType: #BASIC
}  


define view entity I_TimeSheetTaskAcctgCatTxt
  as select from dd07t 
  association [1..1] to I_TimeSheetTaskAccountingCat as _AccountingCat
    on $projection.TimeSheetTaskAccountingCat = _AccountingCat.TimeSheetTaskAccountingCat
  association [0..1] to I_Language as _Language      
    on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
      @ObjectModel.foreignKey.association: '_AccountingCat'
      @ObjectModel.text.element: ['TimeSheetTaskAccountingCatName']
  key cast( dd07t.domvalue_l as tims_task_accounting_category ) as TimeSheetTaskAccountingCat,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as tims_task_accounting_cat_name preserving type ) as TimeSheetTaskAccountingCatName, 
      _AccountingCat,
      _Language
} 
where dd07t.domname  = 'TIMS_TASK_ACCOUNTING_CATEGORY'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'

Learn More