I_SupplierPurchasingOrgTP

@EndUserText.label: 'Supplier Purchasing Org - TP'
@VDM.viewType: #TRANSACTIONAL
@AccessControl: {
   authorizationCheck: #CHECK,
   personalData.blocking: #REQUIRED
}
@ObjectModel:{
 usageType: {
   serviceQuality: #C,
   sizeCategory: #XXL,
   dataClass: #TRANSACTIONAL
  }
}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view entity I_SupplierPurchasingOrgTP
  as select from I_BusinessPartnerPurgOrg as SupplierPurchasingOrg
//  composition [0..*] of I_SupplierPartnerFunctionTP_2 as _SupplierPartnerFunction

  association        to parent I_BusinessPartnerSupplierTP_2 as _BusinessPartnerSupplier    on  $projection.BusinessPartner = _BusinessPartnerSupplier.BusinessPartner
                                                                                            and $projection.Supplier        = _BusinessPartnerSupplier.Supplier
  association [1..1] to I_BusinessPartnerTP_2                as _BusinessPartner            on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_PurchasingOrganization             as _PurgOrganization           on  $projection.PurchasingOrganizationForEdit = _PurgOrganization.PurchasingOrganization
  association [0..1] to I_PurchasingGroup                    as _PurchasingGroup            on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..*] to I_CurrencyText                       as _CurrencyText               on  $projection.PurchaseOrderCurrency = _CurrencyText.Currency
  association [0..*] to C_SchemaGroupTextVHTemp              as _SchemaGroupText            on  $projection.CalculationSchemaGroupCode = _SchemaGroupText.SchemaGroup
  association [0..*] to I_CustomerPaymentTermsText           as _PaymentTermsText           on  $projection.PaymentTerms = _PaymentTermsText.CustomerPaymentTerms
  association [1..*] to C_Pricingdatecontroltextvhtemp       as _PriceDateControlText       on  $projection.PricingDateControl = _PriceDateControlText.PricingDateControl
  association [0..*] to I_IncotermsVersionText               as _IncotermsVersionText       on  $projection.IncotermsVersion = _IncotermsVersionText.IncotermsVersion
  association [0..*] to I_IncotermsClassificationText        as _IncotermsClassfctnText     on  $projection.IncotermsClassification = _IncotermsClassfctnText.IncotermsClassification
  association [0..1] to I_LogisticalRoundingProfile          as _LogisticalRoundingProfile  on  $projection.RoundingProfile = _LogisticalRoundingProfile.LogisticalRoundingProfile

{
  key PurchasingOrganization,
  key BusinessPartner,
  key Supplier,
      @ObjectModel.editableFieldFor: 'PurchasingOrganization'
      PurchasingOrganization                          as PurchasingOrganizationForEdit,
      @ObjectModel.editableFieldFor: 'BusinessPartner'
      BusinessPartner                                 as BusinessPartnerForEdit,
      @ObjectModel.editableFieldFor: 'Supplier'
      Supplier                                        as SupplierForEdit,
      BusinessPartnerUUID,
      PurchasingGroup,
      PlannedDeliveryDurationInDays,
      PurchasingIsBlockedForSupplier,
      SupplierRespSalesPersonName,
      ContactPersonPhoneNumber,
      PurchaseOrderCurrency,
      MinimumOrderAmount,
      CalculationSchemaGroupCode,
      PaymentTerms,
      PricingDateControl,
      SupplierABCClassificationCode,
      ShippingCondition,
      PurOrdAutoGenerationIsAllowed,
      InvoiceIsGoodsReceiptBased,
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,
      EvaldReceiptSettlementIsActive,
      AutomaticEvaluatedRcptSettlmt,
      SupplierAccountNumber,
      SupplierConfirmationControlKey,
      IsOrderAcknRqd,
      //   IsActiveEntity,

      SuplrIsSubjToSubsqntSettlement,
      SuplrPurgOrgAgrmtOfBusVolIsRqd,
      SuplrInvcRevalIsAllowed,
      SuplrPurgOrgIsRlvtForPriceDetn,
      IntrastatCrsBorderTrMode,
      ProductUnitGroup,
      RoundingProfile,
      PlanningCycle,
      SuplrDiscountInKindIsGranted,
      SuplrIsRlvtForSettlmtMgmt,
      InvoiceIsMMServiceEntryBased,
      ProdStockAndSlsDataTransfPrfl,
      EvaldRcptSettlementProfile,
      AbsoluteHandlingSurchargeAmt,
      PercentageHandlingSurchargeAmt,
      MinimumHandlingSurchargeAmt,
      MaximumHandlingSurchargeAmt,
      AutomDebitCrtnIsEnbldOnGI,
      IncotermsSupChnLoc2AddlUUID,
      IncotermsSupChnLoc1AddlUUID,
      IncotermsSupChnDvtgLocAddlUUID,
      cast( 'X' as sdraft_is_active preserving type ) as BPHasActiveEntity,
      DeletionIndicator,

      //     @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      _IncotermsSupChnLoc1.Location                   as IncotermsLocation1Identifier,
      //      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      _IncotermsSupChnLoc2.Location                   as IncotermsLocation2Identifier,
      //      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      _IncotermsSupChnDvtgLoc.Location                as IncotermsDvtgLocIdentifier,
      _SupplierToPartner._Supplier.SupplierAccountGroup,
      _SupplierToPartner._Supplier.AuthorizationGroup as SupplierAuthznGrp,
      _SupplierToPartner._BusinessPartner.AuthorizationGroup,
      _SupplierToPartner._BusinessPartner.IsBusinessPurposeCompleted,

      /* Associations */
      _IncotermsSupChnDvtgLoc,
      _IncotermsSupChnLoc1,
      _IncotermsSupChnLoc2,
      _ShipgCndnValueHelp,
      _ShippingConditionText,
      _SupplierToPartner,
//      _SupplierPartnerFunction,


      _CurrencyText,
      _SchemaGroupText,
      _PaymentTermsText,
      _PriceDateControlText,
      _IncotermsVersionText,
      _IncotermsClassfctnText,
      _PurgOrganization, // for text for Purchasing Org

      _LogisticalRoundingProfile,


      _BusinessPartnerSupplier,
      _BusinessPartner,
      _PurchasingGroup // added for Purchasing group VH


}