I_SuplrInvcItemMaterialAPI01

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ISIITMATAPI01'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Material Item of Supplier Invoice'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@Metadata.ignorePropagatedAnnotations:true
 
define view I_SuplrInvcItemMaterialAPI01
  as select from I_SupplierInvoiceItemMaterial as item
      inner join I_SupplierInvoiceAPI01 on  item.SupplierInvoice = I_SupplierInvoiceAPI01.SupplierInvoice
                                        and item.FiscalYear      = I_SupplierInvoiceAPI01.FiscalYear
     association [1..1] to I_SupplierInvoiceAPI01 as _SupplierInvoiceAPI01 on  $projection.SupplierInvoice = _SupplierInvoiceAPI01.SupplierInvoice
                                                                           and $projection.FiscalYear      = _SupplierInvoiceAPI01.FiscalYear
{
  key item.SupplierInvoice,
  key item.FiscalYear,
  key item.SupplierInvoiceItem,
      item.Material,
      item.ValuationArea,
      item.CompanyCode, 
      item.SuplrInvcItemMaterialPlant as Plant,        
      item.InventoryValuationType,    
      item.DebitCreditCode,    
      item.IsNotCashDiscountLiable,        
      item.TaxCode,
      item.TaxJurisdiction,
      item.TaxCountry,   
      item.TaxDeterminationDate,
      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      item.DocumentCurrency,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      item.SupplierInvoiceItemAmount,     
      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      @Semantics.unitOfMeasure: true
      item.QuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      item.Quantity,           
 
      /* Associations */
      _SupplierInvoiceAPI01,
      item._UnitOfMeasure,
      item._Currency 
}