I_SupDmndAllDocProdnOrdCompBsc

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'ISUPDMNDADCMP3B',
  compiler.compareFilter: true
 }
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #X,
     sizeCategory:   #XXL
   }
}
@EndUserText.label: 'Basic View for Production Order Components'
define view I_SupDmndAllDocProdnOrdCompBsc
  as select from resb                   as resb
    inner join   I_SupDmndMaterialPlant as marc on  resb.matnr = marc.Material
                                                and resb.werks = marc.Plant
    inner join   afpo                   as afpo on resb.aufnr = afpo.aufnr
{
  resb.rsnum              as RequirementDocumentNumber,
  lpad(resb.rspos,6,'0')  as RequirementDocumentItem,
  //  'AR'                                              as RequirementType,

  //  resb.rsart                                        as RecordType,

  resb.bdart              as RequirementType,
  resb.bdter              as RequestedDate,
  resb.bdter              as ProductAvailabilityDate,
  resb.bdter              as RequestedDeliveryDate,
  resb.bdmng              as RequestedRqmtQtyInBaseUnit, //OrderedQuantity

  resb.bdmng              as ConfirmedRqmtQtyInBaseUnit,
  0                       as DeliveredQuantityInBaseUnit,
  resb.enmng              as WithdrawnQuantity, //RequestedRqmtQtyInBaseUnit

  resb.bdmng - resb.enmng as OpenQuantity,
  resb.meins              as BaseUnit,
  resb.matnr              as Material,
  marc.MaterialGroup,
  resb.werks              as Plant,
  resb.bdart              as OrderType,
  marc.CrossPlantConfigurableProduct,
  marc.MaterialType,
  resb.sgt_rcat           as RequirementSegment,
  resb.lgort              as StorageLocation,
  resb.kdauf              as SalesOrder,
  resb.kdpos              as SalesOrderItem,
  marc.SegmentationStrategy,
  marc.SegmentationStrategyScope,
  marc.ProdAvailabilityCheckGroup
}
where
      resb.xloek =  '' -- deleted item should not be selected
  and resb.kzkup =  '' -- coproduct should not be selected
  and resb.kzear =  '' -- final issue for this reservation
  and resb.aufnr <> ''