I_SubscriptionContract

@EndUserText.label: 'Subscription Contract'

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   representativeKey: 'SubscriptionContract',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view entity I_SubscriptionContract
  as select from I_ServiceDocumentEnhcd

  association [0..*] to I_SubscriptionContractItem as _Item                       on  $projection.SubscriptionContract = _Item.SubscriptionContract

  association [0..1] to I_ServiceDocumentStatus    as _SubscriptionContractStatus on  $projection.SubscriptionContractStatus = _SubscriptionContractStatus.ServiceDocumentStatus


  association [0..1] to E_ServiceDocument          as _Extension                  on  _Extension.ServiceCategory       = 'BUS2000266'
                                                                                  and $projection.SubscriptionContract = _Extension.ServiceOrder

{
  key ServiceDocument              as SubscriptionContract,
      ServiceDocumentType          as SubscriptionContractType,
      @Semantics.text: true
      ServiceDocumentDescription   as SubscrpnContractDescription,
      ServiceDocumentUUID          as SubscriptionContractUUID,
      ServiceObjectType,
      ServiceDocumentType,

      Language,
      PostingDate                  as SubscriptionContractPostingDte,

      /* STATUS */
      @ObjectModel.foreignKey.association: '_SubscriptionContractStatus'
      ServiceDocumentStatus        as SubscriptionContractStatus,

      @Semantics.booleanIndicator: true
      case
        when ServiceDocumentStatus = 'C' then 'X'
        when ServiceDocumentStatus <> 'C' then ''
      end                          as SubscrpnContractIsCompleted,

      @Semantics.booleanIndicator: true
      ServiceDocumentHasError      as SubscriptionContractHasError,

      /* PRICING */
      PricingDocument,
      PricingProcedure,

      /* Organizational units with the S/4 SD codes */
      SalesOrganization,
      SalesOffice,
      SalesGroup,

      /* ORGANIZATION UNIT */
      SalesOrganizationOrgUnitID,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      DistributionChannel,
      Division,
      ServiceOrganization,

      /* PARTNER */
      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                as ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee          as RespEmployeeBusinessPartnerId,

      /* EXTERNAL REFERENCE*/
      PurchaseOrderByCustomer,

      ServiceDocumentCreatedByUser as CreatedByUser,
      @Semantics.dateTime:true
      ServiceDocCreationDateTime   as CreationDateTime,
      ServiceDocumentChangedByUser as LastChangedByUser,
      @Semantics.dateTime:true
      ServiceDocChangedDateTime    as LastChangeDateTime,

      //Associations

      _ServiceObjType,
      _SoldToParty,
      _ShipToParty,
      _BillToParty,
      _PayerParty,
      _SalesOrganization,
      _SalesOffice,
      _SalesGroup,
      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _DistributionChannel,
      _Division,
      _ServiceOrganizationOrgUnit_2,
      _ContactPerson,
      _RespEmployee,
      _SubscriptionContractStatus,

      _Item

}
where
  ServiceObjectType = 'BUS2000266'