I_StatisticalKeyFigureDocument

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Statistical Key Figure Document'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #BASIC }
define view entity I_StatisticalKeyFigureDocument 
  as select from cobk

  association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
  
  association [1..1] to I_Currency as _ControllingAreaCurrency   on  $projection.ControllingAreaCurrency = _ControllingAreaCurrency.Currency
  
  association [0..1] to I_ReferenceDocumentType     as _ReferenceDocumentType     on  $projection.ReferenceDocumentType = _ReferenceDocumentType.ReferenceDocumentType
  
  association [0..*] to I_ReferenceDocumentTypeText as _ReferenceDocumentTypeText on  $projection.ReferenceDocumentType = _ReferenceDocumentTypeText.ReferenceDocumentType
                                                                                         
  association [1..1] to I_StstclKeyFigReversalDocument as _ReversalStstclKeyFigureValue on  $projection.ControllingArea    = _ReversalStstclKeyFigureValue.ControllingArea
                                                                                         and $projection.StatisticalKeyFigureDocument = _ReversalStstclKeyFigureValue.ReversedReferenceDocument
 
  //Association to GrantText, BudgetPeriodText and FunctionalAreaText missing yet      


{
      @ObjectModel.foreignKey.association: '_ControllingArea'
  key kokrs                                                     as ControllingArea,
  key belnr                                                     as StatisticalKeyFigureDocument,
      @Semantics.fiscal.period: true
      cast(perab as fins_fiscalperiod preserving type )         as FiscalPeriod,
      cast(gjahr as fis_gjahr_no_conv )                         as FiscalYear,
      vrgng                                                     as ControllingBusTransacType,
      budat                                                     as PostingDate,
      bldat                                                     as DocumentDate,
      cpudt                                                     as StatKeyFigDocumentCreationDate,
      usnam                                                     as StatKeyFigDocumentCreatedBy,
      bltxt                                                     as ControllingDocumentHeaderText,
      stflg                                                     as IsReversalDocument,
      stokz                                                     as IsReversed,
      cast(refbn as reversedreferencedocument preserving type ) as ReversedReferenceDocument,
      cast(wsdat as fin_currconvdat preserving type )           as ExchangeRateDate,
      kurst                                                     as ExchangeRateType,
      @ObjectModel.foreignKey.association: '_ControllingAreaCurrency'
      kwaer                                                     as ControllingAreaCurrency,
      @ObjectModel.foreignKey.association: '_ReferenceDocumentType'
      cast(awtyp as fis_awtyp preserving type )                 as ReferenceDocumentType,
      
      cast(
        case stokz
            when '' then '1'
            else '2'
      end as fcoua_statkeyfigdoc_status) as StstclKeyFigureDocumentStatus,
      
      cast(
        case stokz
            when '' then 3
            else 1
      end as abap.int1 ) as StatusCriticality,
      
      cast(
        case stokz
            when '' then '1'
            else '2'
      end as fco_document_status_text) as StatusName,
      
      cast(
        case stokz
            when '' then ''
         else _ReversalStstclKeyFigureValue.StatisticalKeyFigureDocument
      end as reversalreferencedocument preserving type ) as ReversalReferenceDocument,
      
      cast(
        case stflg
            when '' then '1'
            else '2'
      end as fco_posting_type) as AllocationPostingType,
      
      cast(
        case stflg
            when '' then '1'
            else '2'
      end as  fco_posting_type_text) as AllocationPostingTypeText,
      
      cast( timestmp as vdm_creationdatetime ) as CreationDateTime,
     
      _ControllingArea,
      _ReferenceDocumentType,
      _ControllingAreaCurrency,
      _ReferenceDocumentTypeText
      
}
where
  vrgng = 'RKS'