I_SrvcDocStatusChangeDocument

@AbapCatalog.sqlViewName: 'ISRVCSTATCD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Change Documents for Status'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM: {
  viewType: #COMPOSITE
}
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_SrvcDocStatusChangeDocument
  //Get Service Documents Header

  as select from I_SrvcMgmtObjStsChgInformation
    inner join   I_ServiceDocumentEnhcd as _ServiceDocumentEnhcd on StatusObjectUUID = _ServiceDocumentEnhcd.ServiceDocumentUUID
{
  key cast( SrvcMgmtObjStatusChangeNumber as cdchangenr )                                                                                                                       as ChangeDocument,
  key cast( _ServiceDocumentEnhcd.ServiceDocumentCharUUID  as cdobjectv)                                                      as ChangeDocObject,
  key cast( concat(concat( '000' , _ServiceDocumentEnhcd.ServiceDocumentCharUUID ) , SrvcMgmtObjectStatus) as cdtabkey )                                                        as ChangeDocTableKey,
  key cast(SrvcMgmtObjStsChgInformation as cdchngind )                                                                                                                          as ChangeDocChangeType,
  key SrvcMgmtObjectStatus,
      cast( dats_tims_to_tstmp ( ChangeDocumentStatusDate, ChangeDocumentStatusTime, abap_system_timezone( $session.client,  'NULL' ), $session.client, 'NULL' ) as cdcreated ) as ServiceDocChangedDateTime,
      cast ( SrvcMgmtObjStsChangeUser         as cdusername )                                                                                                                   as CreatedByUser,
      StatusObjectUUID
}

//Get Service Documents Item

union all select from I_SrvcMgmtObjStsChgInformation
  inner join          I_ServiceDocumentItemEnhcd as _ServiceDocumentItemEnhcd on StatusObjectUUID = _ServiceDocumentItemEnhcd.ServiceDocumentItemUUID
{
  key  cast( SrvcMgmtObjStatusChangeNumber as cdchangenr )                                                                                                                       as ChangeDocument,
  key  cast( _ServiceDocumentItemEnhcd._ServiceDocument.ServiceDocumentCharUUID as cdobjectv )                                                                                                    as ChangeDocObject,
  key  cast( concat(concat( '000' , _ServiceDocumentItemEnhcd.ServiceDocumentItemCharUUID ) , SrvcMgmtObjectStatus) as cdtabkey )                                                as ChangeDocTableKey,
  key  cast(SrvcMgmtObjStsChgInformation as cdchngind )                                                                                                                          as ChangeDocChangeType,
  key  SrvcMgmtObjectStatus,
       cast( dats_tims_to_tstmp ( ChangeDocumentStatusDate, ChangeDocumentStatusTime, abap_system_timezone( $session.client,  'NULL' ), $session.client, 'NULL' ) as cdcreated ) as ServiceDocChangedDateTime,
       cast ( SrvcMgmtObjStsChangeUser          as cdusername )                                                                                                                  as CreatedByUser,
       StatusObjectUUID
}

//Get Repa Documents Header

union all select from I_SrvcMgmtObjStsChgInformation
  inner join          I_InHouseRepair as _InHouserepair on StatusObjectUUID = _InHouserepair.InHouseRepairUUID
{
  key cast( SrvcMgmtObjStatusChangeNumber as cdchangenr )                                                                                                                       as ChangeDocument,
  key _InHouserepair.InHouseRepairCharUUID                                                                                                                                      as ChangeDocObject,
  key cast( concat(concat( '000' , _InHouserepair.InHouseRepairCharUUID ) , SrvcMgmtObjectStatus) as cdtabkey )                                                                 as ChangeDocTableKey,
  key cast(SrvcMgmtObjStsChgInformation as cdchngind )                                                                                                                          as ChangeDocChangeType,
  key SrvcMgmtObjectStatus,
      cast( dats_tims_to_tstmp ( ChangeDocumentStatusDate, ChangeDocumentStatusTime, abap_system_timezone( $session.client,  'NULL' ), $session.client, 'NULL' ) as cdcreated ) as ServiceDocChangedDateTime,
      cast ( SrvcMgmtObjStsChangeUser         as cdusername )                                                                                                                   as CreatedByUser,
      StatusObjectUUID
}

//Get Service Documents Item

union all select from I_SrvcMgmtObjStsChgInformation
  inner join          I_InHouseRepairItem as _InHouserepairItem on StatusObjectUUID = _InHouserepairItem.InHouseRepairItemUUID
{
  key cast( SrvcMgmtObjStatusChangeNumber as cdchangenr )                                                                                                                       as ChangeDocument,
  key _InHouserepairItem._InHouseRepair.InHouseRepairCharUUID                                                                                                                   as ChangeDocObject,
  key cast( concat(concat( '000' , _InHouserepairItem.InHouseRepairItemCharUUID ) , SrvcMgmtObjectStatus) as cdtabkey )                                                         as ChangeDocTableKey,
  key cast(SrvcMgmtObjStsChgInformation as cdchngind )                                                                                                                          as ChangeDocChangeType,
  key SrvcMgmtObjectStatus,
      cast( dats_tims_to_tstmp ( ChangeDocumentStatusDate, ChangeDocumentStatusTime, abap_system_timezone( $session.client,  'NULL' ), $session.client, 'NULL' ) as cdcreated ) as ServiceDocChangedDateTime,
      cast ( SrvcMgmtObjStsChangeUser         as cdusername )                                                                                                                   as CreatedByUser,
      StatusObjectUUID
}