I_SlsDocumentItemRelatedObject

DDL: I_SLSDOCUMENTITEMRELATEDOBJECT Type: view_entity BASIC Package: VDM_SD_SLS

Sales Document Item Related Object

I_SlsDocumentItemRelatedObject is a Basic CDS View that provides data about "Sales Document Item Related Object" in SAP S/4HANA. It reads from 3 data sources (I_SDDocumentItemRelatedObject, I_SalesDocumentBasic, I_SalesDocumentItemBasic) and exposes 16 fields with key fields SalesDocument, SalesDocumentItem, SDDocumentCategory, SDDocRelatedObjectSequenceNmbr. Part of development package VDM_SD_SLS.

3 data source(s) 16 fields

Data Sources (3)

SourceAliasJoin Type
I_SDDocumentItemRelatedObject RelatedObject from
I_SalesDocumentBasic SalesDocument inner
I_SalesDocumentItemBasic SalesDocumentItem inner

Annotations (8)

NameValueLevelField
EndUserText.label Sales Document Item Related Object view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view

Fields (16)

KeyFieldSource TableSource FieldDescription
KEY SalesDocument
KEY SalesDocumentItem I_SDDocumentItemRelatedObject SalesDocumentItem
KEY SDDocumentCategory I_SDDocumentItemRelatedObject SDDocumentCategory
KEY SDDocRelatedObjectSequenceNmbr I_SDDocumentItemRelatedObject SDDocRelatedObjectSequenceNmbr
SDDocumentRelatedObjectType I_SDDocumentItemRelatedObject SDDocumentRelatedObjectType
SDDocRelatedObjectSystem I_SDDocumentItemRelatedObject SDDocRelatedObjectSystem
SDDocRelatedObjectReference1 I_SDDocumentItemRelatedObject SDDocRelatedObjectReference1
SDDocRelatedObjectReference2 I_SDDocumentItemRelatedObject SDDocRelatedObjectReference2
SalesDocumentType I_SalesDocumentBasic SalesDocumentType
OrganizationDivision I_SalesDocumentBasic OrganizationDivision
SalesOrganization I_SalesDocumentBasic SalesOrganization
DistributionChannel I_SalesDocumentBasic DistributionChannel
_SalesDocument _SalesDocument
_SalesDocumentItem _SalesDocumentItem
_SDDocumentCategory _SDDocumentCategory
_SDDocumentRelatedObjectType I_SDDocumentItemRelatedObject _SDDocumentRelatedObjectType 
//@ClientHandling.algorithm: #SESSION_VARIABLE 

@EndUserText.label: 'Sales Document Item Related Object'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
//@AbapCatalog: {

//  sqlViewName: 'ISDSLSDOCITRO',

//  compiler.compareFilter: true

//}

@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}
@Metadata.ignorePropagatedAnnotations: true
//@AbapCatalog.preserveKey:true


define view entity I_SlsDocumentItemRelatedObject
  as select from I_SDDocumentItemRelatedObject as RelatedObject
  inner join     I_SalesDocumentItemBasic as SalesDocumentItem on  SalesDocumentItem.SalesDocument     = RelatedObject.SalesDocument
                                                               and SalesDocumentItem.SalesDocumentItem = RelatedObject.SalesDocumentItem
  inner join     I_SalesDocumentBasic     as SalesDocument     on  SalesDocument.SalesDocument         = RelatedObject.SalesDocument                                                          
                                                             
    association[1..1] to I_SalesDocument            as _SalesDocument            on  $projection.SalesDocument     = _SalesDocument.SalesDocument
    
    association[1..1] to I_SalesDocumentItem        as _SalesDocumentItem        on  $projection.SalesDocument     = _SalesDocumentItem.SalesDocument
                                                                                 and $projection.SalesDocumentItem = _SalesDocumentItem.SalesDocumentItem
                                                                                 
    association[0..1] to I_SDDocumentCategory       as _SDDocumentCategory       on $projection.SDDocumentCategory  = _SDDocumentCategory.SDDocumentCategory                                                                              

{
    @ObjectModel.foreignKey.association: '_SalesDocument'                                                                                                   
    key cast(RelatedObject.SalesDocument as vbeln_va preserving type) as SalesDocument,
    
    @ObjectModel.foreignKey.association: '_SalesDocumentItem'                                                                                         
    key RelatedObject.SalesDocumentItem,
    
    @ObjectModel.foreignKey.association: '_SDDocumentCategory'
    key RelatedObject.SDDocumentCategory,

    //@ObjectModel.readOnly: true

    key RelatedObject.SDDocRelatedObjectSequenceNmbr,
    
    @ObjectModel.foreignKey.association: '_SDDocumentRelatedObjectType'
    RelatedObject.SDDocumentRelatedObjectType,
    RelatedObject.SDDocRelatedObjectSystem,
    RelatedObject.SDDocRelatedObjectReference1,
    RelatedObject.SDDocRelatedObjectReference2,     

    @Consumption.hidden: true
    SalesDocument.SalesDocumentType,
    @Consumption.hidden: true
    SalesDocument.OrganizationDivision,
    @Consumption.hidden: true
    SalesDocument.SalesOrganization,
    @Consumption.hidden: true
    SalesDocument.DistributionChannel,

    //Association

    _SalesDocument,
    _SalesDocumentItem,
    _SDDocumentCategory,
    RelatedObject._SDDocumentRelatedObjectType
                
}

Learn More