I_ServiceTeam

DDL: I_SERVICETEAM Type: view BASIC Package: CRMS4_ORG_MGMT

Service Team

I_ServiceTeam is a Basic CDS View that provides data about "Service Team" in SAP S/4HANA. It reads from 2 data sources (hrv1222a, I_BusinessPartner) and exposes 18 fields with key field BusinessPartner. Part of development package CRMS4_ORG_MGMT.

2 data source(s) 18 fields

Data Sources (2)

SourceAliasJoin Type
hrv1222a _Attrib inner
I_BusinessPartner I_BusinessPartner from

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName ISERVICETEAM view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.representativeKey BusinessPartner view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #BASIC view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Service Team view

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY BusinessPartner I_BusinessPartner BusinessPartner
BusinessPartnerName I_BusinessPartner BusinessPartnerName
OrganizationBPName1 I_BusinessPartner OrganizationBPName1
OrganizationBPName2 I_BusinessPartner OrganizationBPName2
AuthorizationGroup I_BusinessPartner AuthorizationGroup
IsBusinessPurposeCompleted I_BusinessPartner IsBusinessPurposeCompleted
DataControllerSet I_BusinessPartner DataControllerSet
DataController1 I_BusinessPartner DataController1
DataController2 I_BusinessPartner DataController2
DataController3 I_BusinessPartner DataController3
DataController4 I_BusinessPartner DataController4
DataController5 I_BusinessPartner DataController5
DataController6 I_BusinessPartner DataController6
DataController7 I_BusinessPartner DataController7
DataController8 I_BusinessPartner DataController8
DataController9 I_BusinessPartner DataController9
DataController10 I_BusinessPartner DataController10
_CurrentDefaultAddress I_BusinessPartner _CurrentDefaultAddress 
@AbapCatalog: {
                 sqlViewName: 'ISERVICETEAM',
                 compiler.compareFilter: true
//                 preserveKey: true

              }
@AccessControl: {
                   authorizationCheck: #CHECK,
                   personalData.blocking: #REQUIRED
                }
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
                 representativeKey: 'BusinessPartner',
                 usageType: {
                               dataClass:      #CUSTOMIZING,
                               serviceQuality: #X,
                               sizeCategory:   #L
                            }
              }
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Service Team'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_ServiceTeam
  as select from   I_BusinessPartner
    inner join(
                   hrp1001  as _hrp1001
        inner join hrv1222a as _Attrib on  _hrp1001.otype = 'O'
                                       and _hrp1001.istat = '1'
                                       and _hrp1001.sclas = 'BP'
                                       and _Attrib.otype  = 'O'
                                       and _Attrib.istat  = '1'
                                       and _Attrib.attrib = 'IS_SE_TGRP'
                                       and _Attrib.low    = 'X'
                                       and _hrp1001.objid = _Attrib.objid
    )
    on I_BusinessPartner.BusinessPartner = _hrp1001.sobid

{

  key I_BusinessPartner.BusinessPartner,

      I_BusinessPartner.BusinessPartnerName,
      I_BusinessPartner.OrganizationBPName1,
      I_BusinessPartner.OrganizationBPName2,
      I_BusinessPartner.AuthorizationGroup,
      @Semantics.booleanIndicator: true
      I_BusinessPartner.IsBusinessPurposeCompleted,

      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController1,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController2,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController3,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController4,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController6,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController7,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController8,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController9,
      //added only for DCL check

      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController10,


      /* Associations */
      I_BusinessPartner._CurrentDefaultAddress

}
where
  I_BusinessPartner.BusinessPartnerCategory = '2'

Learn More