I_ServiceEntrySheetItemBasic

@AbapCatalog.sqlViewName: 'ISRVENTSHTITMBSC'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Service Entry Sheet Item Basic'
@VDM.viewType : #BASIC

@ObjectModel: {
   representativeKey: 'ServiceEntrySheetItem',
   usageType.serviceQuality: #A,
   usageType.sizeCategory: #L,
   usageType.dataClass: #TRANSACTIONAL
}

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_ServiceEntrySheetItemBasic
  as select from mmpur_ses_item as Document

  association [1..1] to I_ServiceEntrySheetBasic       as _ServiceEntrySheet         on  $projection.ServiceEntrySheet = _ServiceEntrySheet.ServiceEntrySheet
  association [1..*] to I_SrvEntrySheetAcctAssgmtBasic as _AccountAssignment         on  $projection.ServiceEntrySheet     = _AccountAssignment.ServiceEntrySheet
                                                                                     and $projection.ServiceEntrySheetItem = _AccountAssignment.ServiceEntrySheetItem
  association [0..1] to I_Material                     as _Material                  on  $projection.Service = _Material.Material
  association [0..1] to I_MaterialGroup                as _MaterialGroup             on  $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_AccountAssignmentCategory    as _AccountAssignmentCategory on  $projection.AccountAssignmentCategory = _AccountAssignmentCategory.AccountAssignmentCategory
  association [0..1] to I_Currency                     as _DocumentCurrency          on  $projection.Currency = _DocumentCurrency.Currency
  association [0..1] to I_UnitOfMeasure                as _UnitValueHelp             on  $projection.QuantityUnit = _UnitValueHelp.UnitOfMeasure
{
      @ObjectModel.foreignKey.association: '_ServiceEntrySheet'
  key Document.serviceentrysheet                                           as  ServiceEntrySheet,

      @ObjectModel.readOnly: true
  key Document.serviceentrysheetitem                                       as  ServiceEntrySheetItem,

      Document.serviceentrysheetuuid                                       as  ServiceEntrySheetUUID,

      Document.serviceentrysheetitemuuid                                   as  ServiceEntrySheetItemUUID,

      @ObjectModel.readOnly: true
      Document.referencepurchaseorder                                      as  PurchaseOrder,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @Consumption.valueHelp: '_PurchaseOrderItemVH'
      Document.referencepurchaseorderitem                                  as  PurchaseOrderItem,

      Document.deletioncode                                                as  IsDeleted,

      @ObjectModel.foreignKey.association: '_Material'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @Consumption.valueHelp: '_Material'
      Document.service                                                     as  Service,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @Semantics.text: true
      Document.description                                                 as  ServiceEntrySheetItemDesc,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @Consumption.valueHelp: '_ServicePerformerValueHelp'
      Document.serviceperformer                                            as  ServicePerformer,

      @ObjectModel.foreignKey.association: '_AccountAssignmentCategory'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @Consumption.valueHelp: '_SrvcEntrShtAcctAssgmtCat'
      Document.accountassignmentcategory                                   as  AccountAssignmentCategory,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.accountassignmentdistribution                               as  MultipleAcctAssgmtDistribution,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @Semantics.text: true
      Document.workitem                                                    as  WorkItem,

      @Aggregation.default: #NONE
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.quantity                                                    as  ConfirmedQuantity,

      @Semantics.unitOfMeasure: true
      Document.orderpriceunit                                              as  OrderPriceUnit,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.orderpriceunittoorderunitnmrtr                              as  OrderPriceUnitToOrderUnitNmrtr,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.ordpriceunittoorderunitdnmntr                               as  OrdPriceUnitToOrderUnitDnmntr,

      @Aggregation.default: #NONE
      @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.qtyinpurchaseorderpriceunit                                 as  QtyInPurchaseOrderPriceUnit,

      @ObjectModel.foreignKey.association: '_UnitValueHelp'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      @Semantics.unitOfMeasure: true
      Document.unit                                                        as  QuantityUnit,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.performancedate                                             as  ServicePerformanceDate,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.performanceenddate                                          as  ServicePerformanceEndDate,

      Document.originobject                                                as  OriginObject,

      @Semantics.amount.currencyCode: 'Currency'
      @Aggregation.default: #NONE
      Document.netamount                                                   as  NetAmount,

      @Semantics.amount.currencyCode: 'Currency'
      @Aggregation.default: #NONE
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      Document.netprice                                                    as  NetPriceAmount,

      @ObjectModel.foreignKey.association: '_MaterialGroup'
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @Consumption.valueHelp: '_MaterialGroup'
      Document.productgroup                                                as  MaterialGroup,

      @ObjectModel.readOnly: true
      Document.crea_uname                                                  as  CreatedByUser,

      @ObjectModel.readOnly: true
      Document.crea_date_time                                              as  CreationDateTime,

      @ObjectModel.readOnly: true
      Document.lchg_date_time                                              as  LastChangeDateTime,

      @ObjectModel.readOnly: true
      Document.lchg_uname                                                  as  LastChangeUser,

      @ObjectModel.readOnly: true
      Document.plant                                                       as  Plant,

      Document.externalreferenceid                                         as  PurgDocItemExternalReference,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.contract                                                    as PurchaseContract,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Document.contractitem                                                as PurchaseContractItem,

      @Aggregation.default: #NONE
      @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
      Document.netpricequantity                                            as NetPriceQuantity,

      @Semantics.amount.currencyCode: 'Currency'
      Document.nondeductibleinputtaxamount                                 as NonDeductibleInputTaxAmount,

      Document.taxcode                                                     as TaxCode,

      Document.taxcountry                                                  as TaxCountry,

      Document.taxdeterminationdate                                        as TaxDeterminationDate,

      Document.taxjurisdiction                                             as TaxJurisdiction,

      Document.taxcalculationprocedure                                     as TaxCalculationProcedure,

      Document.pricedate                                                   as PurgDocPriceDate,
      Document.sesitemisfinalentry                                         as SESItemIsFinalEntry,

      @ObjectModel.readOnly: true
      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_DocumentCurrency'
      _ServiceEntrySheet.Currency                                          as  Currency,

      @ObjectModel.readOnly: true
      _ServiceEntrySheet.PurchasingOrganization                            as  PurchasingOrganization,

      @ObjectModel.readOnly: true
      _ServiceEntrySheet.PurchasingGroup                                   as  PurchasingGroup,

      @ObjectModel.readOnly: true
      _ServiceEntrySheet.IsDeleted                                         as  ParentObjectIsDeleted,

      // Data Privacy and Protection

      @UI.hidden: true
      @Consumption.hidden: true
      @ObjectModel.readOnly: true
      _ServiceEntrySheet.IsEndOfPurposeBlocked,

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT , #TO_COMPOSITION_ROOT ]
      _ServiceEntrySheet,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _AccountAssignment,
      _Material,
      _MaterialGroup,
      _AccountAssignmentCategory,
      _DocumentCurrency,
      _UnitValueHelp
}