I_ServiceDocumentItemPrdcssr_2

@EndUserText.label: 'Preceding Transaction of Srvc Trans Item'
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@Analytics: {
    dataCategory: #FACT,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
            mapping:[
                {
//                   filter: [{operator: #EQ, tableElement: 'objtype_a', value: 'BUS2000%'}],

                    table: 'crmd_brelvonai', role: #MAIN,
                    viewElement: ['ServiceDocumentItmRelationUUID', 'ServiceDocItmRltnSqncNumber'],
                    tableElement: ['relationid', 'posno']
                }
            ]
        }
    }
 }
 
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@AbapCatalog: {
  sqlViewName: 'ISERVDOCITMPRE2',
  compiler.compareFilter: true ,
  preserveKey: true
}

@ObjectModel: {
//   representativeKey: 'ServiceDocumentItmRelationUUID',

   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #A,
     sizeCategory:   #XL
   },
   supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE]
}

//@Analytics.dataCategory: #DIMENSION

//@Metadata.allowExtensions:true

@Metadata.ignorePropagatedAnnotations: true

//! Business Object SONT for the Service Document Item Predecessor

@ObjectModel.sapObjectNodeType.name: 'ServiceDocumentItemPredecessor'
/*
  1902CE: Data preview might give you an error because hextobin conversion may not work on properly on junk data. Hence dump occurs.
  To view the data, you have to apply the condition "CharcLength = 32" to get the results for Service scenario only.

  1911CE: DONOT use hextobin converted attribute.

*/

/*
If there is any new Business object addition in service document view (e.g. BUS2000116 )
then the same business object has to be added in DCL "I_ServiceDocumentItemPrdcssr" as well.
*/

define view I_ServiceDocumentItemPrdcssr_2
  as select from crmd_brelvonai
  association [1] to I_ServiceDocumentItemEnhcd as _ServiceDocItm on $projection.ServiceDocItmPrdcssrCharUUID = _ServiceDocItm.ServiceDocumentItemCharUUID

{
  key relationid                                as ServiceDocumentItmRelationUUID,
  key posno                                     as ServiceDocItmRltnSqncNumber,

      /* CRMT_BRELVONAI */
      cast(objkey_a as crms4_object_charguid32 preserving type ) as ServiceDocItmPrdcssrCharUUID,
      
      cast(objkey_b as crms4_object_charguid32 preserving type ) as ServiceDocumentItemCharUUID,
      breltyp                                   as ServiceDocumentItmRelationType,
      
      objtype_a                                 as ServiceDocItmPrdcssrBusObjType,
      vona_kind                                 as ServiceDocumentItmRelationKind,
      objtype_b                                 as ServiceDocumentItemObjectType,

      //Associations

      _ServiceDocItm

}
where
  objtype_a like 'BUS2000%'