I_ServiceContract

@EndUserText.label: 'Service Contract'

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #NOT_REQUIRED
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
    representativeKey: 'ServiceContract',
    sapObjectNodeType.name: 'ServiceContract',
    supportedCapabilities: [ #ANALYTICAL_DIMENSION, 
                             #CDS_MODELING_ASSOCIATION_TARGET, 
                             #SQL_DATA_SOURCE, 
                             #CDS_MODELING_DATA_SOURCE ],
    modelingPattern: #ANALYTICAL_DIMENSION,
    usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #A,
        sizeCategory:   #XXL
    }
}

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

define view entity I_ServiceContract
  as select from I_ServiceDocument
  
  association [0..1] to I_BusinessPartner       as _RespEmployee          on _RespEmployee.BusinessPartner = $projection.RespEmployeeBusinessPartnerId 
  
  association [0..1] to I_BusinessPartner       as _ContactPerson         on _ContactPerson.BusinessPartner = $projection.ContactPersonBusinessPartnerId
  
  association [0..1] to I_SrvcDocPaymentMethod  as _PaymentMethod         on _PaymentMethod.PaymentMethod             = $projection.PaymentMethod
                                                                         and _PaymentMethod.SalesOrganization         = $projection.SalesOrganization
                                                                         and _PaymentMethod.OrgUnitTypeIDConcatenated = ''

  association [0..1] to E_ServiceDocument       as _ServiceContractExt    on _ServiceContractExt.ServiceCategory = $projection.ServiceObjectType
                                                                         and _ServiceContractExt.ServiceOrder    = $projection.ServiceContract 
{
      // Header Keys

      @ObjectModel.text.element: [ 'ServiceContractDescription' ]
  key ServiceDocument                                                 as ServiceContract,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      
      ServiceDocumentUUID                                             as ServiceContractUUID,
      cast( ServiceDocumentCharUUID as sysuuid_c preserving type )    as ServiceContractCharUUID,

      // Header Details

      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType,
      @Semantics.text: true
      ServiceDocumentDescription                                      as ServiceContractDescription,
      Language,
      PostingDate,
      @Semantics.dateTime: true
      ServiceDocCreationDateTime,
      @Semantics.dateTime: true
      ServiceDocChangedDateTime,
      ServiceDocumentCreatedByUser,
      ServiceDocumentChangedByUser,
      PricingDocument,
      RefBusinessSolutionOrder,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocNetAmount                                             as ServiceContractNetAmount,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocGrossAmount                                           as ServiceContractGrossAmount,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocTaxAmount,
      SoldToParty,
      SoldToPartyRegion,
      SoldToPartyCountry,

      @ObjectModel.foreignKey.association: '_RespEmployee'
      cast( ResponsibleEmployee as crmt_person_resp preserving type ) as RespEmployeeBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      cast( ContactPerson as crmt_contact_person preserving type )    as ContactPersonBusinessPartnerId,

      ShipToParty,
      BillToParty,
      PayerParty,
      
      ServiceContractStartDateTime,
      ServiceContractEndDateTime,
      SrvcContrEarliestStartDateTime,
      SrvcContrLatestEndDateTime,
      PaymentTerms,
      PaymentMethod,
      SrvcSEPAMandateRelevance,
      SEPAMandate,
      WBSElementInternalID,
      TransactionCurrency,
      PurchaseOrderByCustomer,
      CustomerPurchaseOrderDate,
      ServiceDocumentRejectionReason                                  as ServiceContractRejectionReason,
      Region,
      ServiceDocumentStatus                                           as ServiceContractStatus,
      @Semantics.booleanIndicator: true
      ServiceDocumentIsReleased                                       as ServiceContractIsReleased,
      @Semantics.booleanIndicator: true
      ServiceDocumentHasError                                         as ServiceContractHasError,
      ServiceDocBillingStatus                                         as SrvcContrBillingStatus,
      @Semantics.booleanIndicator: true
      ServiceDocumentIsRejected                                       as ServiceContractIsRejected,
      @Semantics.booleanIndicator: true
      ServiceDocumentIsOpen                                           as ServiceContractIsOpen,
      ServiceContractCanclnSts,
      SrvcDocRejectionStatus                                          as SrvcContrRejectionStatus,
      
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      BillingBlockReason,
      ServiceDocumentCanclnParty                                      as ServiceContractCanclnParty,
      ServiceDocumentCanclnReason                                     as ServiceContrCancellationReason,
      SrvcDocCreditStatus                                             as SrvcContrCreditStatus,
      
      _ServiceDocumentType,
      _ServiceObjType,
      _SoldToParty,
      _SoldToPartyRegion,
      _SoldToPartyCountry,
      _RespEmployee,
      _ContactPerson,
      _ShipToParty,
      _BillToParty,
      _PayerParty,
      _PaymentTerms,
      _PaymentMethod,
      _SrvcSEPAMandateRelevance,
      _TransactionCurrency,
      _SrvcDocumentRejectionReason,
      _Region,
      _SrvcDocLifecycleStatus,
      _ServiceDocHasError,
      _ServiceDocBillingStatus,
      _ServiceDocumentIsOpen,
      _ServiceContractCanclnSts,
      _SalesOrganization,
      _SalesOffice,
      _SalesGroup,
      _Division,
      _DistributionChannel,
      _BillingBlockReason,
      _SrvcDocCreditStatus
} where     ServiceObjectType = 'BUS2000112'
        and ServiceDocumentTemplateType is initial
        and ServiceDocumentIsQuotation = ' '