I_SecurityClassBasic

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Security Class Basic'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE,#CDS_MODELING_ASSOCIATION_TARGET,#SEARCHABLE_ENTITY,#SQL_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #M,
  dataClass: #MASTER
}
@VDM.viewType: #BASIC
define view entity I_SecurityClassBasic
  as select from vwpanla as SecurityClass

{
  key cast(ranl as ftr_gen_security_class preserving type)                      as SecurityClass,
      cast(sanlf as ftr_gen_fin_instr_prod_categ preserving type)               as FinancialInstrProductCategory,
      SecurityClass.sstati                                                      as SecurityClassStatus,
      @Semantics.text: true
      cast(SecurityClass.xalkz as ftr_gen_security_class_name preserving type)  as SecurityClassName,
      @Semantics.text: true
      cast(SecurityClass.xallb as ftr_gen_security_class_lname preserving type) as SecurityClassDescription,
      SecurityClass.gsart                                                       as FinancialInstrumentProductType,
      SecurityClass.srolext                                                     as ScrtyClassGenClassification,
      cast(SecurityClass.repke as repke_new preserving type)                    as Issuer,
      SecurityClass.rewhr                                                       as IssueCurrency,
      cast(SecurityClass.bempreis as ftr_sc_bempreis)                           as SecurityClassIssuePriceValue,
      SecurityClass.pemkurs                                                     as IssueRateInPercent,
      SecurityClass.swerttyp                                                    as SecurityClassTransferType,
      SecurityClass.snoti                                                       as SecurityClassQuotation,
      cast( SecurityClass.unit_tick   as ftr_sc_min_unit_num preserving type )  as ScrtyClMinimalNumberOfUnits,
      @Semantics.booleanIndicator
      SecurityClass.sboernot                                                    as SecurityClassIsListed,
      @Semantics.booleanIndicator
      cast( case
        when SecurityClass.sstbe = '1' then 'X'
        else ''
      end as ftr_sc_sstbe preserving type )                                     as ScrtyClassIsRlvtForTaxes,
      SecurityClass.tax_classification                                          as SecurityClassTaxClassification,
      SecurityClass.coicode                                                     as ScrtyClCmplmntyIdnCode,
      SecurityClass.coiland                                                     as ScrtyClCmplmntyIdnCtryReg,
      cast(SecurityClass.rerf as ftr_sc_rerf preserving type)                   as SecurityClassCreatedByUser,
      cast(SecurityClass.derf as ftr_sc_derf preserving type)                   as SecurityClassCreationDate,
      cast(SecurityClass.terf as ftr_sc_terf preserving type)                   as SecurityClassCreationTime,
      cast(SecurityClass.reher as ftr_sc_reher preserving type)                 as SecurityClassCreationSource,
      cast(SecurityClass.rbear as ftr_sc_rbear preserving type)                 as SecurityClassLastChangedByUser,
      cast(SecurityClass.dbear as ftr_sc_dbear preserving type)                 as SecurityClassLastChangedDate,
      cast(SecurityClass.tbear as ftr_sc_tbear preserving type)                 as SecurityClassLastChangedTime,
      cast(SecurityClass.rbher as ftr_sc_rbher preserving type)                 as SecurityClassLastChangedSource,

      //Only in basic level

      @Semantics.booleanIndicator
      SecurityClass.wpfan                                                       as SecurityClassIsPledgeable

}