I_SchedulingRunRequestResult

@EndUserText.label: 'Result of Scheduling Run Request'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.viewEnhancementCategory: [#NONE]
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
    representativeKey: 'SchedulingRunResultUUID',
    usageType: {
      serviceQuality: #A,
      sizeCategory: #L,
      dataClass: #TRANSACTIONAL
    }
}

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity I_SchedulingRunRequestResult
  as select from bps_result
  composition [0..*] of I_SchedgRsltDetermination   as _Determination
  composition [0..*] of I_SchedgRsltWrkgTmeInterval as _Interval
  composition [0..*] of I_SchedulingResultMessage   as _Message
  association        to parent I_SchedulingRunRequest      as _Request on  $projection.SchedulingRunRequestUUID = _Request.SchedulingRunRequestUUID
  association [1..1] to I_SchedulingRun             as _SchedulingRun  on  $projection.SchedulingRunUUID = _SchedulingRun.SchedulingRunUUID
  association [1..1] to I_TimeZoneIANACodeMap       as _IANATimeZone   on  $projection.TimeZoneIANACode = _IANATimeZone.TimeZoneIANACode
  association [0..1] to I_SchedulingActivity        as _Activity       on  $projection.SchedulingActivity = _Activity.SchedulingActivity
  association [0..1] to I_SchedulingDateType        as _StartDateType  on  $projection.SchedulingStartDateType = _StartDateType.SchedulingDateType
  association [0..1] to I_SchedulingDateType        as _EndDateType    on  $projection.SchedulingEndDateType = _EndDateType.SchedulingDateType
  association [0..1] to I_FactoryCalendar           as _Calendar       on  $projection.SchedulingCalendar = _Calendar.FactoryCalendar
  association [0..1] to I_SchedulingWorkingTime     as _WorkingTime    on  $projection.SchedulingWorkingTimeID = _WorkingTime.SchedulingWorkingTimeID
                                                                       and $projection.SchedulingCalendar      = _WorkingTime.SchedulingCalendar
  association [0..1] to I_TimeZone                  as _TimeZone       on  $projection.SchedulingActivityTimeZone = _TimeZone.TimeZoneID
{
  key result_uuid     as SchedulingRunResultUUID,
      @ObjectModel.foreignKey.association: '_Request'
      request_uuid    as SchedulingRunRequestUUID,
      @ObjectModel.foreignKey.association: '_SchedulingRun'
      run_uuid        as SchedulingRunUUID,
      activity_id     as SchedulingActivity,
      sequence_no     as SchedgActivitySequenceNumber,
      timestamp_start as SchedgActivityStartDateTime,
      timestamp_end   as SchedulingActivityEndDateTime,
      @ObjectModel.foreignKey.association: '_Timezone'
      tzone           as SchedulingActivityTimeZone,
      iana_tzone      as TimeZoneIANACode,
      gross_duration  as SchedgGrossDurationInSeconds,
      duration_day    as SchedulingDurationInDays,
      duration_hour   as SchedulingDurationInHours,
      calendar        as SchedulingCalendar,
      working_time    as SchedulingWorkingTimeID,
      date_type_start as SchedulingStartDateType,
      date_type_end   as SchedulingEndDateType,

      _Request,
      _SchedulingRun,
      _Determination,
      _IANATimeZone,
      _Activity,
      _StartDateType,
      _EndDateType,
      _Calendar,
      _WorkingTime,
      _TimeZone,
      _Interval,
      _Message
}