I_SalesOrderSubsqntProcFlow

DDL: I_SALESORDERSUBSQNTPROCFLOW Type: view_entity COMPOSITE Package: VDM_SD_SLS_SO

Subsequent Process Flow of Sales Order

I_SalesOrderSubsqntProcFlow is a Composite CDS View that provides data about "Subsequent Process Flow of Sales Order" in SAP S/4HANA. It reads from 1 data source (I_SalesDocumentSubsqntProcFlow) and exposes 13 fields with key fields SalesOrder, DocRelationshipUUID. It has 1 association to related views. Part of development package VDM_SD_SLS_SO.

1 data source(s) 13 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesDocumentSubsqntProcFlow SubsequentProcFlow from

Associations (1)

CardinalityTargetAliasCondition
[1..1] I_SalesOrder _SalesOrder _SalesOrder.SalesOrder = $projection.SalesOrder

Annotations (8)

NameValueLevelField
EndUserText.label Subsequent Process Flow of Sales Order view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY SalesOrder I_SalesDocumentSubsqntProcFlow SalesDocument
KEY DocRelationshipUUID I_SalesDocumentSubsqntProcFlow DocRelationshipUUID
SubsequentDocument I_SalesDocumentSubsqntProcFlow SubsequentDocument
SubsequentDocumentCategory I_SalesDocumentSubsqntProcFlow SubsequentDocumentCategory
ProcessFlowLevel I_SalesDocumentSubsqntProcFlow ProcessFlowLevel
CreationDate I_SalesDocumentSubsqntProcFlow CreationDate
CreationTime I_SalesDocumentSubsqntProcFlow CreationTime
LastChangeDate I_SalesDocumentSubsqntProcFlow LastChangeDate
SalesOrderType _SalesOrder SalesOrderType
SalesOrganization _SalesOrder SalesOrganization
DistributionChannel _SalesOrder DistributionChannel
OrganizationDivision _SalesOrder OrganizationDivision
_SalesOrder _SalesOrder 
@EndUserText.label: 'Subsequent Process Flow of Sales Order'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
}
@Metadata.ignorePropagatedAnnotations: true

define view entity I_SalesOrderSubsqntProcFlow as select from I_SalesDocumentSubsqntProcFlow as SubsequentProcFlow
  
association [1..1] to I_SalesOrder       as _SalesOrder       on  _SalesOrder.SalesOrder      = $projection.SalesOrder 

{
  key SubsequentProcFlow.SalesDocument as SalesOrder,
  key SubsequentProcFlow.DocRelationshipUUID,
  
      SubsequentProcFlow.SubsequentDocument,
      SubsequentProcFlow.SubsequentDocumentCategory,
      
      SubsequentProcFlow.ProcessFlowLevel,

      @Semantics.systemDate.createdAt: true
      SubsequentProcFlow.CreationDate,
      @Semantics.systemTime.createdAt: true
      SubsequentProcFlow.CreationTime,
      @Semantics.systemDate.lastChangedAt: true
      SubsequentProcFlow.LastChangeDate,

      // For Access control

      @Consumption.hidden: true
      _SalesOrder.SalesOrderType,
      @Consumption.hidden: true
      _SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      _SalesOrder.DistributionChannel,
      @Consumption.hidden: true
      _SalesOrder.OrganizationDivision,

      // Associations

      _SalesOrder
}
where
  SubsequentProcFlow.SDDocumentCategory = 'C'

Learn More