I_SalesDocumentStandardPartner

DDL: I_SALESDOCUMENTSTANDARDPARTNER Type: view COMPOSITE Package: VDM_SD_SLS

Sales Document Standard Partner

I_SalesDocumentStandardPartner is a Composite CDS View that provides data about "Sales Document Standard Partner" in SAP S/4HANA. It reads from 1 data source (I_SalesDocumentBasic) and exposes 10 fields with key field SalesDocument. It has 5 associations to related views. Part of development package VDM_SD_SLS.

1 data source(s) 10 fields

Data Sources (1)

SourceAliasJoin Type
I_SalesDocumentBasic SalesDocument from

Associations (5)

CardinalityTargetAliasCondition
[0..1] I_Customer _SoldToParty $projection.SoldToParty = _SoldToParty.Customer
[0..1] I_Customer _BillToParty $projection.BillToParty = _BillToParty.Customer
[0..1] I_Customer _ShipToParty $projection.ShipToParty = _ShipToParty.Customer
[0..1] I_Customer _PayerParty $projection.PayerParty = _PayerParty.Customer
[1..1] I_SalesDocumentBasic _SalesDocument $projection.SalesDocument = _SalesDocument.SalesDocument

Annotations (11)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Sales Document Standard Partner view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
AccessControl.authorizationCheck #CHECK view
AbapCatalog.sqlViewName ISDSLSSTDPART view
AbapCatalog.compiler.compareFilter true view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
Metadata.ignorePropagatedAnnotations true view

Fields (10)

KeyFieldSource TableSource FieldDescription
KEY SalesDocument SalesDocument
SoldToParty
ShipToParty
BillToParty
PayerParty
_SoldToParty _SoldToParty
_BillToParty _BillToParty
_ShipToParty _ShipToParty
_PayerParty _PayerParty
_SalesDocument _SalesDocument 
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Sales Document Standard Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'ISDSLSSTDPART',
  compiler.compareFilter: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view I_SalesDocumentStandardPartner
  as select from           I_SalesDocumentBasic as SalesDocument

    left outer to one join I_SDDocumentPartner  as SoldToParty on  SalesDocument.SalesDocument = SoldToParty.SDDocument
                                                               and SoldToParty.PartnerFunction = 'AG'
    left outer to one join I_SDDocumentPartner  as ShipToParty on  SalesDocument.SalesDocument = ShipToParty.SDDocument
                                                               and ShipToParty.PartnerFunction = 'WE'
    left outer to one join I_SDDocumentPartner  as BillToParty on  SalesDocument.SalesDocument = BillToParty.SDDocument
                                                               and BillToParty.PartnerFunction = 'RE'
    left outer to one join I_SDDocumentPartner  as PayerParty  on  SalesDocument.SalesDocument = PayerParty.SDDocument
                                                               and PayerParty.PartnerFunction  = 'RG'

  association [0..1] to I_Customer           as _SoldToParty   on $projection.SoldToParty = _SoldToParty.Customer
  association [0..1] to I_Customer           as _BillToParty   on $projection.BillToParty = _BillToParty.Customer
  association [0..1] to I_Customer           as _ShipToParty   on $projection.ShipToParty = _ShipToParty.Customer
  association [0..1] to I_Customer           as _PayerParty    on $projection.PayerParty = _PayerParty.Customer


  association [1..1] to I_SalesDocumentBasic as _SalesDocument on $projection.SalesDocument = _SalesDocument.SalesDocument
{

  key SalesDocument,

      @ObjectModel.foreignKey.association: '_SoldToParty'
      cast(SoldToParty.Customer as kunag preserving type)                             as SoldToParty,

      @ObjectModel.foreignKey.association: '_ShipToParty'
      cast(ShipToParty.Customer as kunwe preserving type)                             as ShipToParty,

      @ObjectModel.foreignKey.association: '_BillToParty'
      cast(BillToParty.Customer as kunre preserving type)                             as BillToParty,

      @ObjectModel.foreignKey.association: '_PayerParty'
      cast(PayerParty.Customer as kunrg preserving type)                              as PayerParty,

      _SoldToParty,
      _BillToParty,
      _ShipToParty,
      _PayerParty,

      _SalesDocument

};

Learn More