I_SalesDocApprovalStatus

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel: {
  dataCategory: #VALUE_HELP,
  representativeKey: 'SalesDocApprovalStatus',
  sapObjectNodeType.name: 'SalesDocApprovalStatus',
  resultSet.sizeCategory: #XS,
  usageType: {
    dataClass: #META,
    serviceQuality: #A,
    sizeCategory: #S
  },
  supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                           #EXTRACTION_DATA_SOURCE,
                           #SQL_DATA_SOURCE,
                           #CDS_MODELING_DATA_SOURCE,
                           #CDS_MODELING_ASSOCIATION_TARGET,
                           #VALUE_HELP_PROVIDER, 
                           #SEARCHABLE_ENTITY],
  modelingPattern: [ #ANALYTICAL_DIMENSION ]
}

@AbapCatalog: {
  sqlViewName: 'ISLSDOCAPPRVLSTS',
  preserveKey:true,
  compiler.compareFilter: true
}

@Analytics: {
  dataCategory: #DIMENSION,
  dataExtraction.enabled: true,
  internalName: #LOCAL
}

@Metadata.ignorePropagatedAnnotations:true
@EndUserText.label: 'Approval Sts for Sales Document'
@Search.searchable: true
@Consumption.ranked: true

define view I_SalesDocApprovalStatus
  as select from dd07l

  association [0..*] to I_SalesDocApprovalStatusT as _Text on $projection.SalesDocApprovalStatus = _Text.SalesDocApprovalStatus

{
      @ObjectModel.text.association: '_Text'
  key cast ( substring(dd07l.domvalue_l, 1, 1) as sd_apm_approval_status preserving type ) as SalesDocApprovalStatus,
      
      @Analytics.hidden: true
      @Consumption.hidden: true
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      domvalue_l as DomainValue,
      
      _Text

}

where
  (
    dd07l.domname  = 'SD_APM_APPROVAL_STATUS'
  )
  and(
    dd07l.as4local = 'A'
  )