I_SDMassChgCkptEntityLevelTxt

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog:{
  sqlViewName: 'ISDMCCENTLVLT',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Mass Chg of Sls Doc Entity Level - Text'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel:{
dataCategory: #TEXT,
modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
representativeKey: 'SlsDocMassChgEntityLevel',
  usageType:{
    dataClass: #META,
    serviceQuality: #A,
    sizeCategory: #S
  },
  supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT,
                          #CDS_MODELING_ASSOCIATION_TARGET,
                          #CDS_MODELING_DATA_SOURCE,
                          #SEARCHABLE_ENTITY,
                          #SQL_DATA_SOURCE]
}
@Search.searchable: true
define view I_SDMassChgCkptEntityLevelTxt
  as select from dd07t
  association [0..1] to I_SDMassChgCkptEntityLevel as _EntityLevel on $projection.SlsDocMassChgEntityLevel = _EntityLevel.SlsDocMassChgEntityLevel
  association [0..1] to I_Language                 as _Language    on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_EntityLevel'
  key cast(SUBSTRING(dd07t.domvalue_l, 1, 1) as sd_mcc_entity_level preserving type) as SlsDocMassChgEntityLevel,

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key ddlanguage                                                                     as Language,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Semantics.text: true
      cast(ddtext as sd_mcc_entity_level_name preserving type)                       as SlsDocMassChgEntityLevelName,

      @Consumption.hidden: true
      dd07t.domvalue_l                                                               as DomainValue,

      //Associations

      _EntityLevel,
      _Language
}
where
  (
    domname  = 'SD_MCC_ENTITY_LEVEL'
  )
  and(
    as4local = 'A'
  )
  and(
    as4vers  = '0000'
  );