I_SDDocumentReason

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'SDDocumentReason'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Order Reason'
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:#NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISDSDDOCREASON' 
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@Metadata.ignorePropagatedAnnotations: true

@Search.searchable: true
@ObjectModel.modelingPattern:           #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities:  [  #SQL_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #ANALYTICAL_DIMENSION, 
                                        #EXTRACTION_DATA_SOURCE,
                                        #SEARCHABLE_ENTITY  ]
@ObjectModel.sapObjectNodeType.name:'SalesDocumentReason'                                        
                                        
define view I_SDDocumentReason
as select from tvau
association [0..*] to I_SDDocumentReasonText  as _Text on $projection.SDDocumentReason = _Text.SDDocumentReason
{   
    @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
    @ObjectModel.text.association: '_Text'
    key augru as SDDocumentReason,
    vauna as RetroBillingUsage,
    vaugv as SelfBillingValueItem,
    //Associations

    _Text
};