I_SAFTJournalHeader

DDL: I_SAFTJOURNALHEADER SQL: IJRNLHDR Type: view COMPOSITE Package: GLO_FIN_IS_SAFT_GEN

SAF-T Journal Header

I_SAFTJournalHeader is a Composite CDS View that provides data about "SAF-T Journal Header" in SAP S/4HANA. It reads from 2 data sources (I_JournalEntry, P_SAFTSumJournalLineItem) and exposes 26 fields with key fields CompanyCode, FiscalYear, AccountingDocument, Ledger. Part of development package GLO_FIN_IS_SAFT_GEN.

2 data source(s) 26 fields

Data Sources (2)

SourceAliasJoin Type
I_JournalEntry JournalHeader from
P_SAFTSumJournalLineItem SumJournalLineItem inner

Parameters (1)

NameTypeDefault
P_Ledger fins_ledger

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName IJRNLHDR view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_INCLUDED view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #COMPOSITE view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label SAF-T Journal Header view

Fields (26)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode I_JournalEntry CompanyCode
KEY FiscalYear I_JournalEntry FiscalYear
KEY AccountingDocument I_JournalEntry AccountingDocument
KEY Ledger P_SAFTSumJournalLineItem Ledger
AccountingDocumentType I_JournalEntry AccountingDocumentType
AccountingDocumentTypeName
AccountingDocumentHeaderText I_JournalEntry AccountingDocumentHeaderText
FiscalPeriod I_JournalEntry FiscalPeriod
PostingDate I_JournalEntry PostingDate
CompanyCodeCurrency P_SAFTSumJournalLineItem CompanyCodeCurrency
TotalGrossAmountInCoCodeCrcy P_SAFTSumJournalLineItem TotalGrossAmountInCoCodeCrcy
AccountingDocumentCreationDate I_JournalEntry AccountingDocumentCreationDate
AccountingDocCreatedByUser I_JournalEntry AccountingDocCreatedByUser
ExchangeRate I_JournalEntry ExchangeRate
DocumentDate I_JournalEntry DocumentDate
TransactionCurrency I_JournalEntry TransactionCurrency
SourceLedger P_SAFTSumJournalLineItem SourceLedger
AccountingDocumentCategory I_JournalEntry AccountingDocumentCategory
OriginalReferenceDocument
ReferenceDocumentType I_JournalEntry ReferenceDocumentType
_CompanyCode I_JournalEntry _CompanyCode
_FiscalYear I_JournalEntry _FiscalYear
_FiscalPeriod I_JournalEntry _FiscalPeriod
_AccountingDocumentType I_JournalEntry _AccountingDocumentType
_Ledger
_CompanyCodeCurrency P_SAFTSumJournalLineItem _CompanyCodeCurrency 
@AbapCatalog.sqlViewName: 'IJRNLHDR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'SAF-T Journal Header'
define view I_SAFTJournalHeader
  with parameters
    P_Ledger : fins_ledger

  as select from I_JournalEntry as JournalHeader

    inner join   P_SAFTSumJournalLineItem as SumJournalLineItem on  SumJournalLineItem.CompanyCode        = JournalHeader.CompanyCode
                                                                and SumJournalLineItem.FiscalYear         = JournalHeader.FiscalYear
                                                                and SumJournalLineItem.AccountingDocument = JournalHeader.AccountingDocument
                                                                and SumJournalLineItem.Ledger             = $parameters.P_Ledger
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key JournalHeader.CompanyCode                                                                                    as CompanyCode,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key JournalHeader.FiscalYear                                                                                     as FiscalYear,
  key JournalHeader.AccountingDocument                                                                             as AccountingDocument,
  key SumJournalLineItem.Ledger                                                                                    as Ledger,

      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      JournalHeader.AccountingDocumentType                                                                         as AccountingDocumentType,
      coalesce(_AccountingDocumentTypeText[1: Language = $session.system_language].AccountingDocumentTypeName,' ') as AccountingDocumentTypeName,

      JournalHeader.AccountingDocumentHeaderText                                                                   as AccountingDocumentHeaderText,
      @ObjectModel.foreignKey.association: '_FiscalPeriod'
      JournalHeader.FiscalPeriod                                                                                   as FiscalPeriod,
      JournalHeader.PostingDate                                                                                    as PostingDate,
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      SumJournalLineItem.CompanyCodeCurrency                                                                       as CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      SumJournalLineItem.TotalGrossAmountInCoCodeCrcy                                                              as TotalGrossAmountInCoCodeCrcy,
           
      case
      when TotalGrossAmountInCoCodeCrcy > 0
       then 'C' //credit - H

      else 'D' //Debit - S

      end                                                                                                          as DebitCreditCode,
      
      JournalHeader.AccountingDocumentCreationDate,
      JournalHeader.AccountingDocCreatedByUser,
      JournalHeader.ExchangeRate,
      JournalHeader.DocumentDate,
      JournalHeader.TransactionCurrency,
      SumJournalLineItem.SourceLedger,
      JournalHeader.AccountingDocumentCategory,
      -- FI-CA Section
      JournalHeader.OriginalReferenceDocument,
      JournalHeader.ReferenceDocumentType,

      //Associations

      JournalHeader._CompanyCode,
      JournalHeader._FiscalYear,
      JournalHeader._FiscalPeriod,
      JournalHeader._AccountingDocumentType,
      -- FI-CA Section
      SumJournalLineItem._Ledger,
      SumJournalLineItem._CompanyCodeCurrency
      
}

Learn More