I_RetsMgmtProcessWthProcgSts

DDL: I_RETSMGMTPROCESSWTHPROCGSTS SQL: IRMRTSWTHPROCGST Type: view COMPOSITE Package: VDM_ARM_BASICS

Returns Mgmt Process With Processing Status

I_RetsMgmtProcessWthProcgSts is a Composite CDS View that provides data about "Returns Mgmt Process With Processing Status" in SAP S/4HANA. It reads from 1 data source (I_RetsMgmtProcWthLogProcgSts) and exposes 7 fields with key field RetsMgmtProcess. It has 1 association to related views. Part of development package VDM_ARM_BASICS.

1 data source(s) 7 fields

Data Sources (1)

SourceAliasJoin Type
I_RetsMgmtProcWthLogProcgSts ProcLogProcgSts from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_RetsMgmtProcgStatus _RetsMgmtProcessingStatus $projection.RetsMgmtProcessingStatus = _RetsMgmtProcessingStatus.RetsMgmtProcessingStatus

Annotations (10)

NameValueLevelField
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.sqlViewName IRMRTSWTHPROCGST view
AbapCatalog.compiler.compareFilter true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
AccessControl.authorizationCheck #NOT_REQUIRED view
VDM.viewType #COMPOSITE view
EndUserText.label Returns Mgmt Process With Processing Status view
Analytics.dataExtraction.enabled false view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY RetsMgmtProcess I_RetsMgmtProcWthLogProcgSts RetsMgmtProcess
ReturnsDocument I_RetsMgmtProcWthLogProcgSts ReturnsDocument
RetsMgmtLogProcgStatus I_RetsMgmtProcWthLogProcgSts RetsMgmtLogProcgStatus
RetsMgmtCompnProcgStatus ProcCompnProcgSts RetsMgmtCompnProcgStatus
_RetsMgmtLogProcgStatus I_RetsMgmtProcWthLogProcgSts _RetsMgmtLogProcgStatus
_RetsMgmtCompnProcgStatus ProcCompnProcgSts _RetsMgmtCompnProcgStatus
_RetsMgmtProcessingStatus _RetsMgmtProcessingStatus 
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IRMRTSWTHPROCGST'
@AbapCatalog.compiler.compareFilter: true

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@AccessControl: {
  authorizationCheck: #NOT_REQUIRED,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  }
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Returns Mgmt Process With Processing Status'
@Analytics.dataExtraction.enabled: false

define view I_RetsMgmtProcessWthProcgSts
  as select from           I_RetsMgmtProcWthLogProcgSts   as ProcLogProcgSts

    left outer to one join I_RetsMgmtProcWthCompnProcgSts as ProcCompnProcgSts on  ProcLogProcgSts.RetsMgmtProcess = ProcCompnProcgSts.RetsMgmtProcess
                                                                               and ProcLogProcgSts.ReturnsDocument = ProcCompnProcgSts.ReturnsDocument

  association [0..1] to I_RetsMgmtProcgStatus as _RetsMgmtProcessingStatus on $projection.RetsMgmtProcessingStatus = _RetsMgmtProcessingStatus.RetsMgmtProcessingStatus

{
      //Key

  key ProcLogProcgSts.RetsMgmtProcess,
      ProcLogProcgSts.ReturnsDocument,

      //Returns Mgmt Process logistical processing status

      ProcLogProcgSts.RetsMgmtLogProcgStatus,

      //Returns Mgmt Process compensation processing status

      ProcCompnProcgSts.RetsMgmtCompnProcgStatus,

      //Returns Mgmt Process processing status

      cast ( case when
        ProcLogProcgSts.RetsMgmtLogProcgStatus = '1' -- <- logistical complete
         and
          (ProcCompnProcgSts.RetsMgmtCompnProcgStatus = '2' -- <- compensation complete
           or ProcCompnProcgSts.RetsMgmtCompnProcgStatus = '' -- <-  not relevant for compensation
           )
            then
            '1' -- -> complete
            else
             case when
              ProcLogProcgSts.RetsMgmtLogProcgStatus = '2'       -- <- logistical error
              or ProcCompnProcgSts.RetsMgmtCompnProcgStatus = '4'    -- <- compensation error
               then
               '2'  -- -> error
               else
               '0'  -- -> open
             end
         end
      as msr_proc_status ) as RetsMgmtProcessingStatus,

      //Associations

      ProcLogProcgSts._RetsMgmtLogProcgStatus,
      ProcCompnProcgSts._RetsMgmtCompnProcgStatus,
      _RetsMgmtProcessingStatus
}

Learn More