I_RetailCharacteristic

DDL: I_RETAILCHARACTERISTIC Type: view_entity BASIC Package: WRF_CHARACTERISTIC_VALUE_GRP

Controlling Characteristics Header

I_RetailCharacteristic is a Basic CDS View (Dimension) that provides data about "Controlling Characteristics Header" in SAP S/4HANA. It reads from 1 data source (wrf_charval_head) and exposes 8 fields with key field CharcInternalID. It has 2 associations to related views. Part of development package WRF_CHARACTERISTIC_VALUE_GRP.

1 data source(s) 8 fields

Data Sources (1)

SourceAliasJoin Type
wrf_charval_head wrf_charval_head from

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_RetailCharacteristicType _RetailCharacteristicType $projection.RetailCharacteristicType = _RetailCharacteristicType.RetailCharacteristicType
[0..1] I_RtlCharcValValdtn _RtlCharcValValdtn $projection.RtlCharcValValdtn = _RtlCharcValValdtn.RtlCharcValValdtn

Annotations (14)

NameValueLevelField
EndUserText.label Controlling Characteristics Header view
AccessControl.authorizationCheck #NOT_REQUIRED view
VDM.viewType #BASIC view
ObjectModel.representativeKey CharcInternalID view
ObjectModel.sapObjectNodeType.name RetailCharacteristicValueType view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
Metadata.ignorePropagatedAnnotations true view
Analytics.internalName #LOCAL view
Analytics.dataCategory #DIMENSION view
Analytics.dataExtraction.enabled true view
Analytics.dataExtraction.delta.changeDataCapture.automatic true view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY CharcInternalID
Characteristic atnam
RetailCharacteristicType chartyp
RtlCharcValValdtn checkopt
LastChangedByUser aenam
LastChangedDate aedat
_RetailCharacteristicType _RetailCharacteristicType
_RtlCharcValValdtn _RtlCharcValValdtn 
//Header Table for Controlling Characteristics

@EndUserText.label: 'Controlling Characteristics Header'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
// Technical Settings

@ObjectModel.representativeKey: 'CharcInternalID'
@ObjectModel.sapObjectNodeType.name: 'RetailCharacteristicValueType'
@ObjectModel: {
 modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [  #CDS_MODELING_DATA_SOURCE,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #EXTRACTION_DATA_SOURCE,
                            #ANALYTICAL_DIMENSION  ],
                            
usageType.dataClass: #MASTER,
usageType.serviceQuality : #A,
usageType.sizeCategory : #S
}

@Metadata.ignorePropagatedAnnotations:true

// For Data Extraction

@Analytics.internalName:  #LOCAL
@Analytics: {
dataCategory: #DIMENSION,
dataExtraction: {
enabled: true,
delta.changeDataCapture: {
automatic: true
    }
  }
}


//View Entity

define view entity I_RetailCharacteristic
  as select from wrf_charval_head
  association [0..1] to I_RetailCharacteristicType as _RetailCharacteristicType on $projection.RetailCharacteristicType = _RetailCharacteristicType.RetailCharacteristicType
  association [0..1] to I_RtlCharcValValdtn        as _RtlCharcValValdtn        on $projection.RtlCharcValValdtn = _RtlCharcValValdtn.RtlCharcValValdtn
{

      @ObjectModel.text.element: ['Characteristic']
  key cast( atinn as numc10 preserving type ) as CharcInternalID,
      @Semantics.text: true
      atnam                                   as Characteristic,
      @ObjectModel.foreignKey.association: '_RetailCharacteristicType'
      chartyp                                 as RetailCharacteristicType,
      @ObjectModel.foreignKey.association: '_RtlCharcValValdtn'
      checkopt                                as RtlCharcValValdtn,
      @Semantics.user.lastChangedBy: true
      aenam                                   as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      aedat                                   as LastChangedDate,

      //Expose Association

      _RetailCharacteristicType,
      _RtlCharcValValdtn

}

Learn More