I_RepairObjectSituation

@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
    personalData.blocking: #('TRANSACTIONAL_DATA'),
    authorizationCheck: #MANDATORY
    }
@ObjectModel: {
    semanticKey:  [ 'RepairObjectCombinedID' ] ,
    uniqueIdField: 'InHouseRepairItemUUID',
    usageType: {
          serviceQuality: #D,
          sizeCategory: #XL,
          dataClass: #MIXED
        }
  }
@EndUserText.label: 'Repair Object Situations'

@ObjectModel.supportedCapabilities:
   [ #SITUATION_ANCHOR, #SITUATION_TRIGGER ]

@Metadata.ignorePropagatedAnnotations: true

define view entity I_RepairObjectSituation
  as select from           I_InHouseRepairItem           as InhRepItem
    inner join             I_InHouseRepair               as InHRepair           on  InHRepair.CustMgmtObjectType = InhRepItem.CustMgmtObjectType
                                                                                and InHRepair.InHouseRepair      = InhRepItem.InHouseRepair
    left outer to one join I_BusinessUserBasic           as RespEmployeeUser    on InHRepair.ResponsibleEmployee = RespEmployeeUser.BusinessPartner

    left outer to one join I_CustMgmtTransactionRelation as TransRelation       on  TransRelation.CustMgmtPrdcssrTransactionUUID = InhRepItem.InHouseRepairItemUUID
                                                                                and TransRelation.CustMgmtTransacRelationType    = 'IHR1'
                                                                                and TransRelation.CustMgmtPrdcssrTransacObjType  = 'BUS2000257'

    left outer to one join P_InHouseRepairItemStatusHist as StatusChangeHistory on StatusChangeHistory.InHouseRepairItemUUID = InhRepItem.InHouseRepairItemUUID

  association [0..1] to E_InHouseRepairItem as _RepairObjectExtension on  $projection.CustMgmtObjectType = _RepairObjectExtension.CustMgmtObjectType
                                                                      and $projection.InHouseRepair      = _RepairObjectExtension.InHouseRepair
                                                                      and $projection.RepairObject       = _RepairObjectExtension.InHouseRepairItem

{

         @UI.hidden: true
  key    InhRepItem.CustMgmtObjectType,

  key    InhRepItem.InHouseRepair                                                                                                                            as InHouseRepair,


  key    InhRepItem.InHouseRepairItem                                                                                                                        as RepairObject,

         @UI.hidden:true
  key    InhRepItem.InHouseRepairItemUUID,

         @Consumption.valueHelpDefinition: [{ entity: { name: 'I_InHouseRepairStatusVH', element: 'InhRepairStatus' }}]
         @EndUserText.label: 'In-House Repair Status'
         cast(InHRepair.InhRepairStatus as crms4_inhrepair_status)                                                                                           as InhRepairStatus,

         @EndUserText.label: 'Repair Object Combined ID'
         cast(
                   concat(concat(InhRepItem.InHouseRepair, '/' ) , InhRepItem.InHouseRepairItem )
                   as crms4_repairorderitm_unique_id preserving type
             )                                                                                                                                               as RepairObjectCombinedID,


         @Consumption.valueHelpDefinition: [{ entity: { name: 'I_InhRepairItemStatusVH', element: 'InhRepairItemStatus' }}]
         cast(InhRepItem.InhRepairItemStatus as crms4_repair_obj_status)                                                                                     as RepairObjectStatus,



         cast( case when  TransRelation.CustMgmtPrdcssrTransacObjType = 'BUS2000257' then 'X'
                      else ' '   end as crms4_repa_ord_ex_boolean preserving type )                                                                          as RepairOrderIsExisting,



         @UI.hidden:true
         RespEmployeeUser.UserID                                                                                                                             as ResponsibleEmployeeUserID,


         //         @UI.hidden:true

         //         InHRepair.ResponsibleEmployee, // Needed for DCL


         @UI.hidden:true
         InhRepItem.InHouseRepairUUID,

         @UI.hidden:true
         InhRepItem.CreatedByUser,

         @UI.hidden: true
         InhRepItem.InhRepairItemCategory,

         @DefaultAggregation: #MAX
         @EndUserText.label:'Number of Days After Repair Object Creation'
         cast(division(  tstmp_seconds_between(InhRepItem.CreationDateTime,tstmp_current_utctimestamp(),'NULL'), 86400, 0 ) as crms4_creation_date_duration) as NrOfDaysAftReprObjCreationDate,

         @DefaultAggregation: #MAX
         @EndUserText.label:'Number of Days Repair Object in Current Status'
         cast(division(  tstmp_seconds_between(StatusChangeHistory.StatusChangedDateTime, tstmp_current_utctimestamp(),'NULL'), 86400, 0 )  as crms4_days_in_current_status)     as NrOfDaysInCurrentStatus,


         /* Due to DCL Inheritence, below fields are needed */
         //required for authorization check

         @UI.hidden: true
         InHRepair.SalesOrganization,
         //required for authorization check

         @UI.hidden: true
         InHRepair.DistributionChannel,
         //required for authorization check

         @UI.hidden: true
         InHRepair.Division,
         //required for authorization check

         @UI.hidden: true
         InHRepair.SalesOffice,
         //required for authorization check

         @UI.hidden: true
         InHRepair.SalesGroup,
         @UI.hidden: true
         InhRepItem.InhRepairType,


         //Associations

         InhRepItem._InHouseRepair,
         InHRepair._SalesOrganization,
         InHRepair._DistributionChannel,
         InHRepair._Division,
         InHRepair._SalesOffice,
         InHRepair._SalesGroup,
         InhRepItem._CustMgmtObjectType,
         // InhRepItem._InhRepairItemStatus,

         InhRepItem._InhRepairItemCategory
         // InHRepair._InhRepairStatus


}
where
  InhRepItem.InhRepairItemIsOpen = 'X' //not completed